7842 - new directory organization

Baremetal is now the default build target and therefore has its sources
at the top-level. Baremetal programs build using the phase-2 Mu toolchain
that requires a Linux kernel. This phase-2 codebase which used to be at
the top-level is now under the linux/ directory. Finally, the phase-2 toolchain,
while self-hosting, has a way to bootstrap from a C implementation, which
is now stored in linux/bootstrap. The bootstrap C implementation uses some
literate programming tools that are now in linux/bootstrap/tools.

So the whole thing has gotten inverted. Each directory should build one
artifact and include the main sources (along with standard library). Tools
used for building it are relegated to sub-directories, even though those
tools are often useful in their own right, and have had lots of interesting
programs written using them.

A couple of things have gotten dropped in this process:
  - I had old ways to run on just a Linux kernel, or with a Soso kernel.
    No more.
  - I had some old tooling for running a single test at the cursor. I haven't
    used that lately. Maybe I'll bring it back one day.

The reorg isn't done yet. Still to do:
  - redo documentation everywhere. All the README files, all other markdown,
    particularly vocabulary.md.
  - clean up how-to-run comments at the start of programs everywhere
  - rethink what to do with the html/ directory. Do we even want to keep
    supporting it?

In spite of these shortcomings, all the scripts at the top-level, linux/
and linux/bootstrap are working. The names of the scripts also feel reasonable.
This is a good milestone to take stock at.

1 files changed, 89 insertions, 0 deletions

diff --git a/shell/cell.mu b/shell/cell.mu
new file mode 100644
index 00000000..59558fb9
--- /dev/null
+++ b/shell/cell.mu
@@ -0,0 +1,89 @@
+type cell {
+  type: int
+  # type 0: pair
+  left: (handle cell)
+  right: (handle cell)
+  # type 1: number
+  number-data: float
+  # type 2: symbol
+  # type 3: string
+  text-data: (handle stream byte)
+  # TODO: array, (associative) table, stream
+}
+
+fn allocate-symbol _out: (addr handle cell) {
+  var out/eax: (addr handle cell) <- copy _out
+  allocate out
+  var out-addr/eax: (addr cell) <- lookup *out
+  var type/ecx: (addr int) <- get out-addr, type
+  copy-to *type, 2/symbol
+  var dest-ah/eax: (addr handle stream byte) <- get out-addr, text-data
+  populate-stream dest-ah, 0x40/max-symbol-size
+}
+
+fn initialize-symbol _out: (addr handle cell), val: (addr array byte) {
+  var out/eax: (addr handle cell) <- copy _out
+  var out-addr/eax: (addr cell) <- lookup *out
+  var dest-ah/eax: (addr handle stream byte) <- get out-addr, text-data
+  var dest/eax: (addr stream byte) <- lookup *dest-ah
+  write dest, val
+}
+
+fn new-symbol out: (addr handle cell), val: (addr array byte) {
+  allocate-symbol out
+  initialize-symbol out, val
+}
+
+fn allocate-number _out: (addr handle cell) {
+  var out/eax: (addr handle cell) <- copy _out
+  allocate out
+  var out-addr/eax: (addr cell) <- lookup *out
+  var type/ecx: (addr int) <- get out-addr, type
+  copy-to *type, 1/number
+}
+
+fn initialize-integer _out: (addr handle cell), n: int {
+  var out/eax: (addr handle cell) <- copy _out
+  var out-addr/eax: (addr cell) <- lookup *out
+  var dest-ah/eax: (addr float) <- get out-addr, number-data
+  var src/xmm0: float <- convert n
+  copy-to *dest-ah, src
+}
+
+fn new-integer out: (addr handle cell), n: int {
+  allocate-number out
+  initialize-integer out, n
+}
+
+fn initialize-float _out: (addr handle cell), n: float {
+  var out/eax: (addr handle cell) <- copy _out
+  var out-addr/eax: (addr cell) <- lookup *out
+  var dest-ah/eax: (addr float) <- get out-addr, number-data
+  var src/xmm0: float <- copy n
+  copy-to *dest-ah, src
+}
+
+fn new-float out: (addr handle cell), n: float {
+  allocate-number out
+  initialize-float out, n
+}
+
+fn allocate-pair _out: (addr handle cell) {
+  var out/eax: (addr handle cell) <- copy _out
+  allocate out
+  # new cells have type pair by default
+}
+
+fn initialize-pair _out: (addr handle cell), left: (handle cell), right: (handle cell) {
+  var out/eax: (addr handle cell) <- copy _out
+  var out-addr/eax: (addr cell) <- lookup *out
+  var dest-ah/ecx: (addr handle cell) <- get out-addr, left
+  copy-handle left, dest-ah
+  dest-ah <- get out-addr, right
+  copy-handle right, dest-ah
+}
+
+fn new-pair out: (addr handle cell), left: (handle cell), right: (handle cell) {
+  allocate-pair out
+  initialize-pair out, left, right
+}