From 71e4f3812982dba2efb471283d310224e8db363e Mon Sep 17 00:00:00 2001
From: "Kartik K. Agaram" <vc@akkartik.com>
Date: Wed, 3 Mar 2021 22:09:50 -0800
Subject: 7842 - new directory organization

Baremetal is now the default build target and therefore has its sources
at the top-level. Baremetal programs build using the phase-2 Mu toolchain
that requires a Linux kernel. This phase-2 codebase which used to be at
the top-level is now under the linux/ directory. Finally, the phase-2 toolchain,
while self-hosting, has a way to bootstrap from a C implementation, which
is now stored in linux/bootstrap. The bootstrap C implementation uses some
literate programming tools that are now in linux/bootstrap/tools.

So the whole thing has gotten inverted. Each directory should build one
artifact and include the main sources (along with standard library). Tools
used for building it are relegated to sub-directories, even though those
tools are often useful in their own right, and have had lots of interesting
programs written using them.

A couple of things have gotten dropped in this process:
  - I had old ways to run on just a Linux kernel, or with a Soso kernel.
    No more.
  - I had some old tooling for running a single test at the cursor. I haven't
    used that lately. Maybe I'll bring it back one day.

The reorg isn't done yet. Still to do:
  - redo documentation everywhere. All the README files, all other markdown,
    particularly vocabulary.md.
  - clean up how-to-run comments at the start of programs everywhere
  - rethink what to do with the html/ directory. Do we even want to keep
    supporting it?

In spite of these shortcomings, all the scripts at the top-level, linux/
and linux/bootstrap are working. The names of the scripts also feel reasonable.
This is a good milestone to take stock at.
---
 linux/303kernel-string.subx | 91 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 91 insertions(+)
 create mode 100644 linux/303kernel-string.subx

(limited to 'linux/303kernel-string.subx')

diff --git a/linux/303kernel-string.subx b/linux/303kernel-string.subx
new file mode 100644
index 00000000..13472cb0
--- /dev/null
+++ b/linux/303kernel-string.subx
@@ -0,0 +1,91 @@
+# We can't really do much with null-terminated kernel strings, and we don't
+# want to. Let's turn them into regular length-prefixed strings at the first
+# opportunity.
+
+== code
+
+kernel-string-to-string:  # ad: (addr allocation-descriptor), in: (addr kernel-string), out: (addr handle array byte)
+    # . prologue
+    55/push-ebp
+    89/<- %ebp 4/r32/esp
+    # . save registers
+    51/push-ecx
+    52/push-edx
+    53/push-ebx
+    56/push-esi
+    57/push-edi
+    # var len/ecx: int = length(in)
+    (kernel-string-length *(ebp+0xc))
+    89/<- %ecx 0/r32/eax
+    # result = allocate-array(ad, len)
+    (allocate-array *(ebp+8) %ecx *(ebp+0x10))
+    # var c/edx: byte = 0
+    ba/copy-to-edx 0/imm32
+    # var src/esi: (addr byte) = in
+    8b/-> *(ebp+0xc) 6/r32/esi
+    # var dest/edi: (addr byte) = result->data
+    8b/-> *(ebp+0x10) 7/r32/edi
+    (lookup *edi *(edi+4))  # => eax
+    8d/copy-address *(eax+4) 7/r32/edi
+    {
+$kernel-string-to-string:loop:
+      # c = *src
+      8a/byte-> *esi 2/r32/dl
+      # if (c == 0) break
+      81 7/subop/compare %edx 0/imm32
+      74/jump-if-= break/disp8
+      # *dest = c
+      88/byte<- *edi 2/r32/dl
+      # ++src
+      46/increment-esi
+      # ++dest
+      47/increment-edi
+      eb/jump loop/disp8
+    }
+$kernel-string-to-string:end:
+    # . restore registers
+    5f/pop-to-edi
+    5e/pop-to-esi
+    5b/pop-to-ebx
+    5a/pop-to-edx
+    59/pop-to-ecx
+    # . epilogue
+    89/<- %esp 5/r32/ebp
+    5d/pop-to-ebp
+    c3/return
+
+kernel-string-length:  # in: (addr kernel-string) -> result/eax: int
+    # . prologue
+    55/push-ebp
+    89/<- %ebp 4/r32/esp
+    # . save registers
+    51/push-ecx
+    52/push-edx
+    # result = 0
+    b8/copy-to-eax 0/imm32
+    # var c/ecx: byte = 0
+    b9/copy-to-ecx 0/imm32
+    # var curr/edx: (addr byte) = in
+    8b/-> *(ebp+8) 2/r32/edx
+    {
+$kernel-string-length:loop:
+      # c = *curr
+      8a/byte-> *edx 1/r32/ecx
+      # if (c == 0) break
+      81 7/subop/compare %ecx 0/imm32
+      74/jump-if-= break/disp8
+      # ++curr
+      42/increment-edx
+      # ++result
+      40/increment-eax
+      #
+      eb/jump loop/disp8
+    }
+$kernel-string-length:end:
+    # . restore registers
+    5a/pop-to-edx
+    59/pop-to-ecx
+    # . epilogue
+    89/<- %esp 5/r32/ebp
+    5d/pop-to-ebp
+    c3/return
-- 
cgit 1.4.1-2-gfad0