1 # _write: write to a file descriptor (fd)
 2 
 3 == code
 4 #   instruction                     effective address                                                   register    displacement    immediate
 5 # . op          subop               mod             rm32          base        index         scale       r32
 6 # . 1-3 bytes   3 bits              2 bits          3 bits        3 bits      3 bits        2 bits      2 bits      0/1/2/4 bytes   0/1/2/4 bytes
 7 
 8 Entry:  # just exit; can't test _write just yet
 9     # . syscall(exit, 0)
10     bb/copy-to-ebx  0/imm32
11     b8/copy-to-eax  1/imm32/exit
12     cd/syscall  0x80/imm8
13 
14 _write:  # fd : int, s : (address array byte)
15     # . prologue
16     55/push-ebp
17     89/copy                         3/mod/direct    5/rm32/ebp    .           .             .           4/r32/esp   .               .                 # copy esp to ebp
18     # . save registers
19     50/push-eax
20     51/push-ecx
21     52/push-edx
22     53/push-ebx
23     # syscall(write, fd, (data) s+4, (size) *s)
24     # . fd : ebx
25     8b/copy                         1/mod/*+disp8   5/rm32/ebp    .           .             .           3/r32/ebx   8/disp8         .                 # copy *(ebp+8) to ebx
26     # . data : ecx = s+4
27     8b/copy                         1/mod/*+disp8   5/rm32/ebp    .           .             .           1/r32/ecx   0xc/disp8       .                 # copy *(ebp+12) to ecx
28     81          0/subop/add         3/mod/direct    1/rm32/ecx    .           .             .           .           .               4/imm32           # add to ecx
29     # . size : edx = *s
30     8b/copy                         1/mod/*+disp8   5/rm32/ebp    .           .             .           2/r32/edx   0xc/disp8       .                 # copy *(ebp+12) to edx
31     8b/copy                         0/mod/indirect  2/rm32/edx    .           .             .           2/r32/edx   .               .                 # copy *edx to edx
32     # . syscall
33     b8/copy-to-eax  4/imm32/write
34     cd/syscall  0x80/imm8
35     # if (eax < 0) abort
36     3d/compare-eax-with  0/imm32
37     0f 8c/jump-if-lesser  $_write:abort/disp32
38 $_write:end:
39     # . restore registers
40     5b/pop-to-ebx
41     5a/pop-to-edx
42     59/pop-to-ecx
43     58/pop-to-eax
44     # . epilogue
45     89/copy                         3/mod/direct    4/rm32/esp    .           .             .           5/r32/ebp   .               .                 # copy ebp to esp
46     5d/pop-to-ebp
47     c3/return
48 
49 $_write:abort:
50     # can't write a message here for risk of an infinite loop, so we'll use a special exit code instead
51     # . syscall(exit, 255)
52     bb/copy-to-ebx  0xff/imm32
53     b8/copy-to-eax  1/imm32/exit
54     cd/syscall  0x80/imm8
55     # never gets here
56 
57 # . . vim:nowrap:textwidth=0