1 # streams: data structure for operating on arrays in a stateful manner
 2 #
 3 # A stream looks like this:
 4 #   write : int  # index at which writes go
 5 #   read : int  # index that we've read until
 6 #   data : (array byte)  # prefixed by length as usual
 7 #
 8 # some primitives for operating on streams:
 9 #   - clear-stream (clears everything but the data length)
10 #   - rewind-stream (resets read pointer)
11 
12 == code
13 #   instruction                     effective address                                                   register    displacement    immediate
14 # . op          subop               mod             rm32          base        index         scale       r32
15 # . 1-3 bytes   3 bits              2 bits          3 bits        3 bits      3 bits        2 bits      2 bits      0/1/2/4 bytes   0/1/2/4 bytes
16 
17 clear-stream:  # f : (address stream)
18     # . prologue
19     55/push-ebp
20     89/copy                         3/mod/direct    5/rm32/ebp    .           .             .           4/r32/esp   .               .                 # copy esp to ebp
21     # . save registers
22     50/push-eax
23     51/push-ecx
24     # eax = f
25     8b/copy                         1/mod/*+disp8   5/rm32/ebp    .           .                         0/r32/eax   8/disp8         .                 # copy *(ebp+8) to eax
26     # ecx = f->length
27     8b/copy                         1/mod/*+disp8   0/rm32/eax    .           .             .           1/r32/ecx   8/disp8         .                 # copy *(eax+8) to ecx
28     # ecx = &f->data[f->length]
29     8d/copy-address                 1/mod/*+disp8   4/rm32/sib    0/base/eax  1/index/ecx   .           1/r32/ecx   0xc/disp8       .                 # copy eax+ecx+12 to ecx
30     # f->write = 0
31     c7          0/subop/copy        0/mod/direct    0/rm32/eax    .           .             .           .           .               0/imm32           # copy to *eax
32     # f->read = 0
33     c7          0/subop/copy        1/mod/*+disp8   0/rm32/eax    .           .             .           .           4/disp8         0/imm32           # copy to *(eax+4)
34     # eax = f->data
35     81          0/subop/add         3/mod/direct    0/rm32/eax    .           .             .           .           .               0xc/imm32         # add to eax
36 $clear-stream:loop:
37     # if (eax >= ecx) break
38     39/compare                      3/mod/direct    0/rm32/eax    .           .             .           1/r32/ecx   .               .                 # compare eax with ecx
39     73/jump-if-greater-or-equal-unsigned  $clear-stream:end/disp8
40     # *eax = 0
41     c6          0/subop/copy-byte   0/mod/direct    0/rm32/eax    .           .             .           .           .               0/imm8            # copy byte to *eax
42     # ++eax
43     40/increment-eax
44     eb/jump  $clear-stream:loop/disp8
45 $clear-stream:end:
46     # . restore registers
47     59/pop-to-ecx
48     58/pop-to-eax
49     # . epilogue
50     89/copy                         3/mod/direct    4/rm32/esp    .           .             .           5/r32/ebp   .               .                 # copy ebp to esp
51     5d/pop-to-ebp
52     c3/return
53 
54 rewind-stream:  # f : (address stream)
55     # . prologue
56     55/push-ebp
57     89/copy                         3/mod/direct    5/rm32/ebp    .           .             .           4/r32/esp   .               .                 # copy esp to ebp
58     # . save registers
59     50/push-eax
60     # eax = f
61     8b/copy                         1/mod/*+disp8   5/rm32/ebp    .           .                         0/r32/eax   8/disp8         .                 # copy *(ebp+8) to eax
62     # f->read = 0
63     c7          0/subop/copy        1/mod/*+disp8   0/rm32/eax    .           .             .           .           4/disp8         0/imm32           # copy to *(eax+4)
64 $rewind-stream:end:
65     # . restore registers
66     58/pop-to-eax
67     # . epilogue
68     89/copy                         3/mod/direct    4/rm32/esp    .           .             .           5/r32/ebp   .               .                 # copy ebp to esp
69     5d/pop-to-ebp
70     c3/return
71 
72 # . . vim:nowrap:textwidth=0