1 # write: like _write, but also support in-memory streams in addition to file
  2 # descriptors.
  3 #
  4 # Our first dependency-injected and testable primitive. We can pass it either
  5 # a file descriptor or an address to a stream. If a file descriptor is passed
  6 # in, we _write to it using the right syscall. If a 'fake file descriptor' or
  7 # stream is passed in, we append to the stream. This lets us redirect output
  8 # in tests and check it later.
  9 #
 10 # We assume our data segment will never begin at an address shorter than
 11 # 0x08000000, so any smaller arguments are assumed to be real file descriptors.
 12 #
 13 # A stream looks like this:
 14 #   read: int  # index at which to read next
 15 #   write: int  # index at which writes go
 16 #   data: (array byte)  # prefixed by length as usual
 17 
 18 == code
 19 #   instruction                     effective address                                                   register    displacement    immediate
 20 # . op          subop               mod             rm32          base        index         scale       r32
 21 # . 1-3 bytes   3 bits              2 bits          3 bits        3 bits      3 bits        2 bits      2 bits      0/1/2/4 bytes   0/1/2/4 bytes
 22 
 23 # TODO: come up with a way to signal when a write to disk fails
 24 write:  # f : fd or (address stream byte), s : (address array byte)
 25     # . prologue
 26     55/push-ebp
 27     89/copy                         3/mod/direct    5/rm32/ebp    .           .             .           4/r32/esp   .               .                 # copy esp to ebp
 28     # if (f < 0x08000000) _write(f, s) and return  # f can't be a user-mode address, so treat it as a kernel file descriptor
 29     81          7/subop/compare     1/mod/*+disp8   5/rm32/ebp    .           .             .           .           8/disp8         0x08000000/imm32  # compare *(ebp+8)
 30     73/jump-if-greater-unsigned-or-equal  $write:fake/disp8
 31     # . . push args
 32     ff          6/subop/push        1/mod/*+disp8   5/rm32/ebp    .           .             .           .           0xc/disp8       .                 # push *(ebp+12)
 33     ff          6/subop/push        1/mod/*+disp8   5/rm32/ebp    .           .             .           .           8/disp8         .                 # push *(ebp+8)
 34     # . . call
 35     e8/call  _write/disp32
 36     # . . discard args
 37     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               8/imm32           # add to esp
 38     eb/jump  $write:end/disp8
 39 $write:fake:
 40     # otherwise, treat 'f' as a stream to append to
 41     # . save registers
 42     50/push-eax
 43     51/push-ecx
 44     52/push-edx
 45     53/push-ebx
 46     # ecx = f
 47     8b/copy                         1/mod/*+disp8   5/rm32/ebp    .           .                         1/r32/ecx   8/disp8         .                 # copy *(ebp+8) to ecx
 48     # edx = f->write
 49     8b/copy                         0/mod/indirect  1/rm32/ecx    .           .             .           2/r32/edx   .               .                 # copy *ecx to edx
 50     # ebx = f->length
 51     8b/copy                         1/mod/*+disp8   1/rm32/ecx    .           .             .           3/r32/ebx   8/disp8         .                 # copy *(ecx+8) to ebx
 52     # eax = _append-3(&f->data[f->write], &f->data[f->length], s)
 53     # . . push s
 54     ff          6/subop/push        1/mod/*+disp8   5/rm32/ebp    .           .             .           .           0xc/disp8       .                 # push *(ebp+12)
 55     # . . push &f->data[f->length]
 56     8d/copy-address                 1/mod/*+disp8   4/rm32/sib    1/base/ecx  3/index/ebx   .           3/r32/ebx   0xc/disp8       .                 # copy ecx+ebx+12 to ebx
 57     53/push-ebx
 58     # . . push &f->data[f->write]
 59     8d/copy-address                 1/mod/*+disp8   4/rm32/sib    1/base/ecx  2/index/edx   .           3/r32/ebx   0xc/disp8       .                 # copy ecx+edx+12 to ebx
 60     53/push-ebx
 61     # . . call
 62     e8/call  _append-3/disp32
 63     # . . discard args
 64     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               0xc/imm32         # add to esp
 65     # f->write += eax
 66     01/add                          0/mod/indirect  1/rm32/ecx    .           .             .           0/r32/eax   .               .                 # add eax to *ecx
 67     # . restore registers
 68     5b/pop-to-ebx
 69     5a/pop-to-edx
 70     59/pop-to-ecx
 71     58/pop-to-eax
 72 $write:end:
 73     # . epilogue
 74     89/copy                         3/mod/direct    4/rm32/esp    .           .             .           5/r32/ebp   .               .                 # copy ebp to esp
 75     5d/pop-to-ebp
 76     c3/return
 77 
 78 test-write-single:
 79     # clear-stream(_test-stream)
 80     # . . push args
 81     68/push  _test-stream/imm32
 82     # . . call
 83     e8/call  clear-stream/disp32
 84     # . . discard args
 85     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               4/imm32           # add to esp
 86     # write(_test-stream, "Ab")
 87     # . . push args
 88     68/push  "Ab"/imm32
 89     68/push  _test-stream/imm32
 90     # . . call
 91     e8/call  write/disp32
 92     # . . discard args
 93     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               8/imm32           # add to esp
 94     # check-ints-equal(*_test-stream->data, 41/A 62/b 00 00, msg)
 95     # . . push args
 96     68/push  "F - test-write-single"/imm32
 97     68/push  0x006241/imm32/Ab
 98     # . . push *_test-stream->data
 99     b8/copy-to-eax  _test-stream/imm32
100     ff          6/subop/push        1/mod/*+disp8   0/rm32/eax    .           .             .           .           0xc/disp8       .                 # push *(eax+12)
101     # . . call
102     e8/call  check-ints-equal/disp32
103     # . . discard args
104     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               0xc/imm32         # add to esp
105     # end
106     c3/return
107 
108 test-write-appends:
109     # clear-stream(_test-stream)
110     # . . push args
111     68/push  _test-stream/imm32
112     # . . call
113     e8/call  clear-stream/disp32
114     # . . discard args
115     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               4/imm32           # add to esp
116     # write(_test-stream, "C")
117     # . . push args
118     68/push  "C"/imm32
119     68/push  _test-stream/imm32
120     # . . call
121     e8/call  write/disp32
122     # . . discard args
123     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               8/imm32           # add to esp
124     # write(_test-stream, "D")
125     # . . push args
126     68/push  "D"/imm32
127     68/push  _test-stream/imm32
128     # . . call
129     e8/call  write/disp32
130     # . . discard args
131     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               8/imm32           # add to esp
132     # check-ints-equal(*_test-stream->data, 43/C 44/D 00 00, msg)
133     # . . push args
134     68/push  "F - test-write-appends"/imm32
135     68/push  0x00004443/imm32/C-D
136     # . . push *_test-stream->data
137     b8/copy-to-eax  _test-stream/imm32
138     ff          6/subop/push        1/mod/*+disp8   0/rm32/eax    .           .             .           .           0xc/disp8       .                 # push *(eax+12)
139     # . . call
140     e8/call  check-ints-equal/disp32
141     # . . discard args
142     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               0xc/imm32         # add to esp
143     # end
144     c3/return
145 
146 == data
147 
148 _test-stream:  # (ref stream byte)
149     # current write index
150     0/imm32
151     # current read index
152     0/imm32
153     # length
154     0x10/imm32
155     # data (2 lines x 8 bytes/line)
156     00 00 00 00 00 00 00 00
157     00 00 00 00 00 00 00 00
158 
159 # . . vim:nowrap:textwidth=0