1 # Helper to allocate a stream on the heap.
  2 
  3 == code
  4 #   instruction                     effective address                                                   register    displacement    immediate
  5 # . op          subop               mod             rm32          base        index         scale       r32
  6 # . 1-3 bytes   3 bits              2 bits          3 bits        3 bits      3 bits        2 bits      2 bits      0/1/2/4 bytes   0/1/2/4 bytes
  7 
  8 new-stream:  # ad : (addr allocation-descriptor), length : int, elemsize : int -> address/eax : (handle stream _)
  9     # . prologue
 10     55/push-ebp
 11     89/copy                         3/mod/direct    5/rm32/ebp    .           .             .           4/r32/esp   .               .                 # copy esp to ebp
 12     # . save registers
 13     52/push-edx
 14     # var n/eax : int = elemsize * length + 12 (for read, write and length)
 15     # . eax = elemsize
 16     8b/copy                         1/mod/*+disp8   5/rm32/ebp    .           .             .           0/r32/eax   0x10/disp8      .                 # copy *(ebp+16) to eax
 17     # . eax *= length
 18     31/xor                          3/mod/direct    2/rm32/edx    .           .             .           2/r32/edx   .               .                 # clear edx
 19     f7          4/subop/multiply    1/mod/*+disp8   5/rm32/ebp    .           .                                     0xc/disp8       .                 # multiply *(ebp+12) into eax
 20     # . if overflow abort
 21     81          7/subop/compare     3/mod/direct    2/rm32/edx    .           .             .           .           .               0/imm32           # compare edx
 22     75/jump-if-!=  $new-stream:abort/disp8
 23     # . edx = elemsize*length
 24     89/copy                         3/mod/direct    2/rm32/edx    .           .             .           0/r32/eax   .               .                 # copy eax to edx
 25     # . eax += 12
 26     05/add-to-eax  0xc/imm32
 27     # var eax : (handle stream _) = allocate(ad, n)
 28     # . . push args
 29     50/push-eax
 30     ff          6/subop/push        1/mod/*+disp8   5/rm32/ebp    .           .             .           .           8/disp8         .                 # push *(ebp+8)
 31     # . . call
 32     e8/call  allocate/disp32
 33     # . . discard args
 34     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               8/imm32           # add to esp
 35     # eax->length = elemsize*length
 36     89/copy                         1/mod/*+disp8   0/rm32/eax    .           .             .           2/r32/edx   8/disp8         .                 # copy edx to *(eax+8)
 37     # clear-stream(eax)
 38     # . . push args
 39     50/push-eax
 40     # . . call
 41     e8/call  clear-stream/disp32
 42     # . . discard args
 43     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               4/imm32           # add to esp
 44 $new-stream:end:
 45     # . restore registers
 46     5a/pop-to-edx
 47     # . epilogue
 48     89/copy                         3/mod/direct    4/rm32/esp    .           .             .           5/r32/ebp   .               .                 # copy ebp to esp
 49     5d/pop-to-ebp
 50     c3/return
 51 
 52 $new-stream:abort:
 53     # . _write(2/stderr, error)
 54     # . . push args
 55     68/push  "new-stream: size too large\n"/imm32
 56     68/push  2/imm32/stderr
 57     # . . call
 58     e8/call  _write/disp32
 59     # . . discard args
 60     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               8/imm32           # add to esp
 61     # . syscall(exit, 1)
 62     bb/copy-to-ebx  1/imm32
 63     b8/copy-to-eax  1/imm32/exit
 64     cd/syscall  0x80/imm8
 65     # never gets here
 66 
 67 test-new-stream:
 68     # . prologue
 69     55/push-ebp
 70     89/copy                         3/mod/direct    5/rm32/ebp    .           .             .           4/r32/esp   .               .                 # copy esp to ebp
 71     # var heap/ecx : allocation-descriptor
 72     68/push  0/imm32/limit
 73     68/push  0/imm32/curr
 74     89/copy                         3/mod/direct    1/rm32/ecx    .           .             .           4/r32/esp   .               .                 # copy esp to ecx
 75     # heap = new-segment(512)
 76     # . . push args
 77     51/push-ecx
 78     68/push  0x200/imm32
 79     # . . call
 80     e8/call  new-segment/disp32
 81     # . . discard args
 82     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               8/imm32           # add to esp
 83     # var start/edx = ad->curr
 84     8b/copy                         0/mod/indirect  1/rm32/ecx    .           .             .           2/r32/edx   .               .                 # copy *ecx to edx
 85     # var eax : (handle stream byte) = new-stream(heap, 3, 2)
 86     # . . push args
 87     68/push  2/imm32
 88     68/push  3/imm32
 89     51/push-ecx
 90     # . . call
 91     e8/call  new-stream/disp32
 92     # . . discard args
 93     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               0xc/imm32         # add to esp
 94     # check-ints-equal(eax, edx, msg)
 95     # . . push args
 96     68/push  "F - test-new-stream: returns current pointer of allocation descriptor"/imm32
 97     52/push-edx
 98     50/push-eax
 99     # . . call
100     e8/call  check-ints-equal/disp32
101     # . . discard args
102     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               0xc/imm32         # add to esp
103     # check-ints-equal(eax->length, 6, msg)
104     # . . push args
105     68/push  "F - test-new-stream: sets length correctly"/imm32
106     68/push  6/imm32
107     ff          6/subop/push        1/mod/*+disp8   0/rm32/eax    .           .             .           .           .               8/disp8           # push *(eax+8)
108     # . . call
109     e8/call  check-ints-equal/disp32
110     # . . discard args
111     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               0xc/imm32         # add to esp
112     # the rest is delegated to clear-stream() so we won't bother checking it
113     # . epilogue
114     89/copy                         3/mod/direct    4/rm32/esp    .           .             .           5/r32/ebp   .               .                 # copy ebp to esp
115     5d/pop-to-ebp
116     c3/return
117 
118 # . . vim:nowrap:textwidth=0