1 == code
  2 #   instruction                     effective address                                                   register    displacement    immediate
  3 # . op          subop               mod             rm32          base        index         scale       r32
  4 # . 1-3 bytes   3 bits              2 bits          3 bits        3 bits      3 bits        2 bits      2 bits      0/1/2/4 bytes   0/1/2/4 bytes
  5 
  6 # write an entire stream's contents to a buffered-file
  7 # ways to do this:
  8 #   - construct a 'maximal slice' and pass it to write-slice-buffered
  9 #   - flush the buffered-file and pass the stream directly to its fd (disabling buffering)
 10 # we'll go with the first way for now
 11 write-stream-data:  # f : (address buffered-file), s : (address stream) -> <void>
 12     # . prolog
 13     55/push-ebp
 14     89/copy                         3/mod/direct    5/rm32/ebp    .           .             .           4/r32/esp   .               .                 # copy esp to ebp
 15     # . save registers
 16     50/push-eax
 17     51/push-ecx
 18     56/push-esi
 19     # esi = s
 20     8b/copy                         1/mod/*+disp8   5/rm32/ebp    .           .             .           6/r32/esi   0xc/disp8       .                 # copy *(ebp+12) to esi
 21     # var slice/ecx = {s->data, s->data + s->write}
 22     # . push s->data + s->write
 23     8b/copy                         0/mod/indirect  6/rm32/esi    .           .             .           0/r32/eax   .               .                 # copy *esi to eax
 24     8d/copy-address                 1/mod/*+disp8   4/rm32/sib    6/base/esi  0/index/eax   .           0/r32/eax   0xc/disp8       .                 # copy esi+eax+12 to eax
 25     50/push-eax
 26     # . push s->data
 27     8d/copy-address                 1/mod/*+disp8   6/rm32/esi    .           .             .           0/r32/eax   0xc/disp8       .                 # copy esi+12 to eax
 28     50/push-eax
 29     # . ecx = esp
 30     89/copy                         3/mod/direct    1/rm32/ecx    .           .             .           4/r32/esp   .               .                 # copy esp to ecx
 31     # write-slice-buffered(f, slice)
 32     # . . push args
 33     51/push-ecx
 34     ff          6/subop/push        1/mod/*+disp8   5/rm32/ebp    .           .             .           .           8/disp8         .                 # push *(ebp+8)
 35     # . . call
 36     e8/call  write-slice-buffered/disp32
 37     # . . discard args
 38     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               8/imm32           # add to esp
 39 $write-stream-data:end:
 40     # . restore locals
 41     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               8/imm32           # add to esp
 42     # . restore registers
 43     5e/pop-to-esi
 44     59/pop-to-ecx
 45     58/pop-to-eax
 46     # . epilog
 47     89/copy                         3/mod/direct    4/rm32/esp    .           .             .           5/r32/ebp   .               .                 # copy ebp to esp
 48     5d/pop-to-ebp
 49     c3/return
 50 
 51 test-write-stream-data:
 52     # . prolog
 53     55/push-ebp
 54     89/copy                         3/mod/direct    5/rm32/ebp    .           .             .           4/r32/esp   .               .                 # copy esp to ebp
 55     # setup
 56     # . clear-stream(_test-output-stream)
 57     # . . push args
 58     68/push  _test-output-stream/imm32
 59     # . . call
 60     e8/call  clear-stream/disp32
 61     # . . discard args
 62     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               4/imm32           # add to esp
 63     # . clear-stream(_test-output-buffered-file+4)
 64     # . . push args
 65     b8/copy-to-eax  _test-output-buffered-file/imm32
 66     05/add-to-eax  4/imm32
 67     50/push-eax
 68     # . . call
 69     e8/call  clear-stream/disp32
 70     # . . discard args
 71     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               4/imm32           # add to esp
 72     # . clear-stream(_test-input-stream)
 73     # . . push args
 74     68/push  _test-input-stream/imm32
 75     # . . call
 76     e8/call  clear-stream/disp32
 77     # . . discard args
 78     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               4/imm32           # add to esp
 79     # initialize input
 80     # . write(_test-input-stream, "abcd")
 81     # . . push args
 82     68/push  "abcd"/imm32
 83     68/push  _test-input-stream/imm32
 84     # . . call
 85     e8/call  write/disp32
 86     # . . discard args
 87     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               8/imm32           # add to esp
 88     # write-stream-data(_test-output-buffered-file, _test-input-stream)
 89     # . . push args
 90     68/push  _test-input-stream/imm32
 91     68/push  _test-output-buffered-file/imm32
 92     # . . call
 93     e8/call  write-stream-data/disp32
 94     # . . discard args
 95     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               8/imm32           # add to esp
 96     # check that the write happened as expected
 97     # . flush(_test-output-buffered-file)
 98     # . . push args
 99     68/push  _test-output-buffered-file/imm32
100     # . . call
101     e8/call  flush/disp32
102     # . . discard args
103     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               4/imm32           # add to esp
104     # . check-stream-equal(_test-output-stream, "abcd", msg)
105     # . . push args
106     68/push  "F - test-write-stream-data"/imm32
107     68/push  "abcd"/imm32
108     68/push  _test-output-stream/imm32
109     # . . call
110     e8/call  check-stream-equal/disp32
111     # . . discard args
112     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               0xc/imm32         # add to esp
113     # . epilog
114     89/copy                         3/mod/direct    4/rm32/esp    .           .             .           5/r32/ebp   .               .                 # copy ebp to esp
115     5d/pop-to-ebp
116     c3/return