1 # Helper to print an int32 in decimal.
  2 
  3 == code
  4 #   instruction                     effective address                                                   register    displacement    immediate
  5 # . op          subop               mod             rm32          base        index         scale       r32
  6 # . 1-3 bytes   3 bits              2 bits          3 bits        3 bits      3 bits        2 bits      2 bits      0/1/2/4 bytes   0/1/2/4 bytes
  7 
  8 write-int32-decimal:  # out: (addr stream byte), n: int
  9     # works by generating characters from lowest to highest and pushing them
 10     # to the stack, before popping them one by one into the stream
 11     #
 12     # pseudocode:
 13     #   push sentinel
 14     #   eax = abs(n)
 15     #   while true
 16     #     sign-extend eax into edx
 17     #     eax, edx = eax/10, eax%10
 18     #     edx += '0'
 19     #     push edx
 20     #     if (eax == 0) break
 21     #   if n < 0
 22     #     push '-'
 23     #   w = out->write
 24     #   curr = &out->data[out->write]
 25     #   max = &out->data[out->size]
 26     #   while true
 27     #     pop into eax
 28     #     if (eax == sentinel) break
 29     #     if (curr >= max) abort
 30     #     *curr = AL
 31     #     ++curr
 32     #     ++w
 33     #   out->write = w
 34     # (based on K&R itoa: https://en.wikibooks.org/wiki/C_Programming/stdlib.h/itoa)
 35     # (this pseudocode contains registers because operations like division
 36     # require specific registers in x86)
 37     #
 38     # . prologue
 39     55/push-ebp
 40     89/copy                         3/mod/direct    5/rm32/ebp    .           .             .           4/r32/esp   .               .                 # copy esp to ebp
 41     # . save registers
 42     50/push-eax
 43     51/push-ecx
 44     52/push-edx
 45     53/push-ebx
 46     57/push-edi
 47     # const ten/ecx = 10
 48     b9/copy-to-ecx  0xa/imm32
 49     # push sentinel
 50     68/push  0/imm32/sentinel
 51     # var eax: int = abs(n)
 52     8b/copy                         1/mod/*+disp8   5/rm32/ebp    .           .             .           0/r32/eax   0xc/disp8       .                 # copy *(ebp+12) to eax
 53     3d/compare-eax-with  0/imm32
 54     7d/jump-if->=  $write-int32-decimal:read-loop/disp8
 55 $write-int32-decimal:negative:
 56     f7          3/subop/negate      3/mod/direct    0/rm32/eax    .           .             .           .           .               .                 # negate eax
 57 $write-int32-decimal:read-loop:
 58     # eax, edx = eax / 10, eax % 10
 59     99/sign-extend-eax-into-edx
 60     f7          7/subop/idiv        3/mod/direct    1/rm32/ecx    .           .             .           .           .               .                 # divide edx:eax by ecx, storing quotient in eax and remainder in edx
 61     # edx += '0'
 62     81          0/subop/add         3/mod/direct    2/rm32/edx    .           .             .           .           .               0x30/imm32        # add to edx
 63     # push edx
 64     52/push-edx
 65     # if (eax == 0) break
 66     3d/compare-eax-and  0/imm32
 67     7f/jump-if->  $write-int32-decimal:read-loop/disp8
 68 $write-int32-decimal:read-break:
 69     # if (n < 0) push('-')
 70     81          7/subop/compare     1/mod/*+disp8   5/rm32/ebp    .           .             .           .           0xc/disp8       0/imm32           # compare *(ebp+12)
 71     7d/jump-if->=  $write-int32-decimal:write/disp8
 72 $write-int32-decimal:push-negative:
 73     68/push  0x2d/imm32/-
 74 $write-int32-decimal:write:
 75     # edi = out
 76     8b/copy                         1/mod/*+disp8   5/rm32/ebp    .           .             .           7/r32/edi   8/disp8         .                 # copy *(ebp+8) to edi
 77     # var w/edx: int = out->write
 78     8b/copy                         0/mod/indirect  7/rm32/edi    .           .             .           2/r32/edx   .               .                 # copy *edi to edx
 79     # var curr/ecx: (addr byte) = &out->data[out->write]
 80     8d/copy-address                 1/mod/*+disp8   4/rm32/sib    7/base/edi  2/index/edx   .           1/r32/ecx   0xc/disp8       .                 # copy ebx+edx+12 to ecx
 81     # var max/ebx: (addr byte) = &out->data[out->size]
 82     8b/copy                         1/mod/*+disp8   7/rm32/edi    .           .             .           3/r32/ebx   8/disp8         .                 # copy *(edi+8) to ebx
 83     8d/copy-address                 1/mod/*+disp8   4/rm32/sib    7/base/edi  3/index/ebx   .           3/r32/ebx   0xc/disp8       .                 # copy edi+ebx+12 to ebx
 84 $write-int32-decimal:write-loop:
 85     # pop into eax
 86     58/pop-to-eax
 87     # if (eax == sentinel) break
 88     3d/compare-eax-and  0/imm32/sentinel
 89     74/jump-if-=  $write-int32-decimal:write-break/disp8
 90     # if (curr >= max) abort
 91     39/compare                      3/mod/direct    1/rm32/ecx    .           .             .           3/r32/ebx   .               .                 # compare ecx with ebx
 92     73/jump-if-addr>=  $write-int32-decimal:abort/disp8
 93 $write-int32-decimal:write-char:
 94     # *curr = AL
 95     88/copy-byte                    0/mod/indirect  1/rm32/ecx    .           .             .           0/r32/AL    .               .                 # copy AL to byte at *ecx
 96     # ++curr
 97     41/increment-ecx
 98     # ++w
 99     42/increment-edx
100     eb/jump  $write-int32-decimal:write-loop/disp8
101 $write-int32-decimal:write-break:
102     # out->write = w
103     89/copy                         0/mod/indirect  7/rm32/edi    .           .             .           2/r32/edx   .               .                 # copy edx to *edi
104 $write-int32-decimal:end:
105     # . restore registers
106     5f/pop-to-edi
107     5b/pop-to-ebx
108     5a/pop-to-edx
109     59/pop-to-ecx
110     58/pop-to-eax
111     # . epilogue
112     89/copy                         3/mod/direct    4/rm32/esp    .           .             .           5/r32/ebp   .               .                 # copy ebp to esp
113     5d/pop-to-ebp
114     c3/return
115 
116 $write-int32-decimal:abort:
117     (draw-text-wrapping-right-then-down-from-cursor-over-full-screen 0 "write-int32-decimal: stream out of space" 3 0)  # 3=cyan
118     {
119       eb/jump loop/disp8
120     }
121     # never gets here
122 
123 test-write-int32-decimal:
124     # - check that a single-digit number converts correctly
125     # setup
126     # . clear-stream(_test-stream)
127     # . . push args
128     68/push  _test-stream/imm32
129     # . . call
130     e8/call  clear-stream/disp32
131     # . . discard args
132     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               4/imm32           # add to esp
133     # write-int32-decimal(_test-stream, 9)
134     # . . push args
135     68/push  9/imm32
136     68/push  _test-stream/imm32
137     # . . call
138     e8/call  write-int32-decimal/disp32
139     # . . discard args
140     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               8/imm32           # add to esp
141     # check-stream-equal(_test-stream, "9", msg)
142     # . . push args
143     68/push  "F - test-write-int32-decimal"/imm32
144     68/push  "9"/imm32
145     68/push  _test-stream/imm32
146     # . . call
147     e8/call  check-stream-equal/disp32
148     # . . discard args
149     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               0xc/imm32         # add to esp
150     # . end
151     c3/return
152 
153 test-write-int32-decimal-zero:
154     # - check that 0 converts correctly
155     # setup
156     # . clear-stream(_test-stream)
157     # . . push args
158     68/push  _test-stream/imm32
159     # . . call
160     e8/call  clear-stream/disp32
161     # . . discard args
162     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               4/imm32           # add to esp
163     # write-int32-decimal(_test-stream, 0)
164     # . . push args
165     68/push  0/imm32
166     68/push  _test-stream/imm32
167     # . . call
168     e8/call  write-int32-decimal/disp32
169     # . . discard args
170     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               8/imm32           # add to esp
171     # check-stream-equal(_test-stream, "0", msg)
172     # . . push args
173     68/push  "F - test-write-int32-decimal-zero"/imm32
174     68/push  "0"/imm32
175     68/push  _test-stream/imm32
176     # . . call
177     e8/call  check-stream-equal/disp32
178     # . . discard args
179     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               0xc/imm32         # add to esp
180     # . end
181     c3/return
182 
183 test-write-int32-decimal-multiple-digits:
184     # - check that a multi-digit number converts correctly
185     # setup
186     # . clear-stream(_test-stream)
187     # . . push args
188     68/push  _test-stream/imm32
189     # . . call
190     e8/call  clear-stream/disp32
191     # . . discard args
192     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               4/imm32           # add to esp
193     # write-int32-decimal(_test-stream, 10)
194     # . . push args
195     68/push  0xa/imm32
196     68/push  _test-stream/imm32
197     # . . call
198     e8/call  write-int32-decimal/disp32
199     # . . discard args
200     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               8/imm32           # add to esp
201     # check-stream-equal(_test-stream, "10", msg)
202     # . . push args
203     68/push  "F - test-write-int32-decimal-multiple-digits"/imm32
204     68/push  "10"/imm32
205     68/push  _test-stream/imm32
206     # . . call
207     e8/call  check-stream-equal/disp32
208     # . . discard args
209     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               0xc/imm32         # add to esp
210     # . end
211     c3/return
212 
213 test-write-int32-decimal-negative:
214     # - check that a negative single-digit number converts correctly
215     # setup
216     # . clear-stream(_test-stream)
217     # . . push args
218     68/push  _test-stream/imm32
219     # . . call
220     e8/call  clear-stream/disp32
221     # . . discard args
222     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               4/imm32           # add to esp
223     # write-int32-decimal(_test-stream, -9)
224     # . . push args
225     68/push  -9/imm32
226     68/push  _test-stream/imm32
227     # . . call
228     e8/call  write-int32-decimal/disp32
229     # . . discard args
230     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               8/imm32           # add to esp
231 +-- 26 lines: #?     # dump _test-stream ------------------------------------------------------------------------------------------------------------------------------------------------
257     # check-stream-equal(_test-stream, "-9", msg)
258     # . . push args
259     68/push  "F - test-write-int32-decimal-negative"/imm32
260     68/push  "-9"/imm32
261     68/push  _test-stream/imm32
262     # . . call
263     e8/call  check-stream-equal/disp32
264     # . . discard args
265     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               0xc/imm32         # add to esp
266     # . end
267     c3/return
268 
269 test-write-int32-decimal-negative-multiple-digits:
270     # - check that a multi-digit number converts correctly
271     # setup
272     # . clear-stream(_test-stream)
273     # . . push args
274     68/push  _test-stream/imm32
275     # . . call
276     e8/call  clear-stream/disp32
277     # . . discard args
278     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               4/imm32           # add to esp
279     # write-int32-decimal(_test-stream, -10)
280     # . . push args
281     68/push  -0xa/imm32
282     68/push  _test-stream/imm32
283     # . . call
284     e8/call  write-int32-decimal/disp32
285     # . . discard args
286     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               8/imm32           # add to esp
287     # check-stream-equal(_test-stream, "-10", msg)
288     # . . push args
289     68/push  "F - test-write-int32-decimal-negative-multiple-digits"/imm32
290     68/push  "-10"/imm32
291     68/push  _test-stream/imm32
292     # . . call
293     e8/call  check-stream-equal/disp32
294     # . . discard args
295     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               0xc/imm32         # add to esp
296     # . end
297     c3/return
298 
299 decimal-digit?:  # c: grapheme -> result/eax: boolean
300     # . prologue
301     55/push-ebp
302     89/copy                         3/mod/direct    5/rm32/ebp    .           .             .           4/r32/esp   .               .                 # copy esp to ebp
303     # . save registers
304     51/push-ecx
305     # ecx = c
306     8b/copy                         1/mod/*+disp8   5/rm32/ebp    .           .             .           1/r32/ecx   8/disp8         .                 # copy *(ebp+8) to ecx
307     # result = false
308     b8/copy-to-eax  0/imm32/false
309     # return false if c < '0'
310     81          7/subop/compare     3/mod/direct    1/rm32/ecx    .           .             .           .           .               0x30/imm32        # compare ecx
311     7c/jump-if-<  $decimal-digit?:end/disp8
312     # return (c <= '9')
313     81          7/subop/compare     3/mod/direct    1/rm32/ecx    .           .             .           .           .               0x39/imm32        # compare ecx
314     7f/jump-if->  $decimal-digit?:end/disp8
315 $decimal-digit?:true:
316     b8/copy-to-eax  1/imm32/true
317 $decimal-digit?:end:
318     # . restore registers
319     59/pop-to-ecx
320     # . epilogue
321     89/copy                         3/mod/direct    4/rm32/esp    .           .             .           5/r32/ebp   .               .                 # copy ebp to esp
322     5d/pop-to-ebp
323     c3/return
324 
325 test-decimal-digit-below-0:
326     # eax = decimal-digit?(0x2f)
327     # . . push args
328     68/push  0x2f/imm32
329     # . . call
330     e8/call  decimal-digit?/disp32
331     # . . discard args
332     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               4/imm32           # add to esp
333     # check-ints-equal(eax, 0, msg)
334     # . . push args
335     68/push  "F - test-decimal-digit-below-0"/imm32
336     68/push  0/imm32/false
337     50/push-eax
338     # . . call
339     e8/call  check-ints-equal/disp32
340     # . . discard args
341     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               0xc/imm32         # add to esp
342     c3/return
343 
344 test-decimal-digit-0-to-9:
345     # eax = decimal-digit?(0x30)
346     # . . push args
347     68/push  0x30/imm32
348     # . . call
349     e8/call  decimal-digit?/disp32
350     # . . discard args
351     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               4/imm32           # add to esp
352     # check-ints-equal(eax, 1, msg)
353     # . . push args
354     68/push  "F - test-decimal-digit-at-0"/imm32
355     68/push  1/imm32/true
356     50/push-eax
357     # . . call
358     e8/call  check-ints-equal/disp32
359     # . . discard args
360     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               0xc/imm32         # add to esp
361     # eax = decimal-digit?(0x39)
362     # . . push args
363     68/push  0x39/imm32
364     # . . call
365     e8/call  decimal-digit?/disp32
366     # . . discard args
367     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               4/imm32           # add to esp
368     # check-ints-equal(eax, 1, msg)
369     # . . push args
370     68/push  "F - test-decimal-digit-at-9"/imm32
371     68/push  1/imm32/true
372     50/push-eax
373     # . . call
374     e8/call  check-ints-equal/disp32
375     # . . discard args
376     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               0xc/imm32         # add to esp
377     c3/return
378 
379 test-decimal-digit-above-9:
380     # eax = decimal-digit?(0x3a)
381     # . . push args
382     68/push  0x3a/imm32
383     # . . call
384     e8/call  decimal-digit?/disp32
385     # . . discard args
386     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               4/imm32           # add to esp
387     # check-ints-equal(eax, 0, msg)
388     # . . push args
389     68/push  "F - test-decimal-digit-above-9"/imm32
390     68/push  0/imm32/false
391     50/push-eax
392     # . . call
393     e8/call  check-ints-equal/disp32
394     # . . discard args
395     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               0xc/imm32         # add to esp
396     c3/return
397 
398 to-decimal-digit:  # in: grapheme -> out/eax: int
399     # . prologue
400     55/push-ebp
401     89/copy                         3/mod/direct    5/rm32/ebp    .           .             .           4/r32/esp   .               .                 # copy esp to ebp
402     # eax = in
403     8b/copy                         1/mod/*+disp8   5/rm32/ebp    .           .             .           0/r32/eax   8/disp8         .                 # copy *(ebp+8) to eax
404 $to-decimal-digit:check0:
405     # if (eax < '0') goto abort
406     3d/compare-eax-with  0x30/imm32/0
407     7c/jump-if-<  $to-decimal-digit:abort/disp8
408 $to-decimal-digit:check1:
409     # if (eax > '9') goto abort
410     3d/compare-eax-with  0x39/imm32/f
411     7f/jump-if->  $to-decimal-digit:abort/disp8
412 $to-decimal-digit:digit:
413     # return eax - '0'
414     2d/subtract-from-eax  0x30/imm32/0
415 $to-decimal-digit:end:
416     # . epilogue
417     89/copy                         3/mod/direct    4/rm32/esp    .           .             .           5/r32/ebp   .               .                 # copy ebp to esp
418     5d/pop-to-ebp
419     c3/return
420 
421 $to-decimal-digit:abort:
422     (draw-text-wrapping-right-then-down-from-cursor-over-full-screen 0 "to-decimal-digit: not a digit character" 3 0)  # 3=cyan
423     {
424       eb/jump loop/disp8
425     }
426     # never gets here
427 
428 # . . vim:nowrap:textwidth=0