1 # Render text with word-wrap.
  2 #
  3 # To run:
  4 #   $ ./translate_mu apps/browse.mu
  5 #   $ ./a.elf __text_file__
  6 #
  7 # Press 'q' to quit. All other keys scroll down.
  8 
  9 fn main args-on-stack: (addr array (addr array byte)) -> exit-status/ebx: int {
 10 +-- 20 lines: # var file/esi: (addr buffered-file) = open args-on-stack[1] for reading --------------------------------------------------------------------------------------------------
 30   enable-screen-grid-mode
 31   var nrows/eax: int <- copy 0
 32   var ncols/ecx: int <- copy 0
 33   nrows, ncols <- screen-size 0
 34   enable-keyboard-immediate-mode
 35   {
 36     render file, nrows, ncols
 37     var key/eax: byte <- read-key
 38     compare key, 0x71  # 'q'
 39     loop-if-!=
 40   }
 41   enable-keyboard-type-mode
 42   enable-screen-type-mode
 43   exit-status <- copy 0
 44 }
 45 
 46 type render-state {
 47   current-state: int  # enum 0: normal, 1: bold
 48 }
 49 
 50 # decide how to lay out pages on screen
 51 fn render in: (addr buffered-file), nrows: int, ncols: int {
 52   # Fit multiple pages on screen on separate columns, each wide enough to read
 53   # comfortably.
 54   # Pages are separated horizontally by a 'page margin'. Among other reasons,
 55   # this allows the odd line to bleed out on the right if necessary.
 56   #
 57   # hardcoded parameters:
 58   #   top-margin
 59   #   page-margin
 60   #   page-width
 61   var _r: render-state
 62   var r/edi: (addr render-state) <- address _r
 63   var toprow/eax: int <- copy 2  # top-margin
 64   var botrow/ecx: int <- copy nrows
 65   var leftcol/edx: int <- copy 5  # page-margin
 66   var rightcol/ebx: int <- copy leftcol
 67   rightcol <- add 0x40  # page-width = 64 characters
 68   start-color 0, 0xec, 7  # 236 = darkish gray
 69   {
 70     compare rightcol, ncols
 71     break-if->=
 72     render-page in, toprow, leftcol, botrow, rightcol, r
 73     leftcol <- copy rightcol
 74     leftcol <- add 5  # page-margin
 75     rightcol <- copy leftcol
 76     rightcol <- add 0x40  # page-width
 77     loop
 78   }
 79 }
 80 
 81 fn render-page in: (addr buffered-file), toprow: int, leftcol: int, botrow: int, rightcol: int, r: (addr render-state) {
 82   clear toprow, leftcol, botrow, rightcol
 83   # render screen rows
 84   var row/ecx: int <- copy toprow
 85 $line-loop: {
 86     compare row, botrow
 87     break-if->=
 88     var col/edx: int <- copy leftcol
 89     move-cursor 0, row, col
 90     {
 91       compare col, rightcol
 92       break-if->=
 93       var c/eax: byte <- read-byte-buffered in
 94       compare c, 0xffffffff  # EOF marker
 95       break-if-= $line-loop
 96       update-attributes c, r
 97       compare c, 0xa  # newline
 98       break-if-=  # no need to print newlines
 99       var g/eax: grapheme <- copy c
100       print-grapheme 0, g
101       col <- increment
102       loop
103     }
104     row <- increment
105     loop
106   }
107 }
108 
109 fn update-attributes c: byte, _r: (addr render-state) {
110   var r/edi: (addr render-state) <- copy _r
111   var state/esi: (addr int) <- get r, current-state
112 $update-attributes:check-state: {
113     compare *state, 0  # normal
114     {
115       break-if-!=
116       compare c, 0x2a  # '*'
117       {
118         break-if-!=
119         # r->current-state == 0 && c == '*'
120         start-bold 0
121         copy-to *state, 1
122         break $update-attributes:check-state
123       }
124       compare c, 0x5f  # '_'
125       {
126         break-if-!=
127         # r->current-state == 0 && c == '_'
128         start-bold 0
129         copy-to *state, 1
130         break $update-attributes:check-state
131       }
132       break $update-attributes:check-state
133     }
134     {
135       break-if-=
136       compare c, 0x2a  # '*'
137       {
138         break-if-!=
139         # r->current-state == 1 && c == '*'
140         reset-formatting 0
141         copy-to *state, 0
142         break $update-attributes:check-state
143       }
144       compare c, 0x5f  # '_'
145       {
146         break-if-!=
147         # r->current-state == 1 && c == '_'
148         reset-formatting 0
149         copy-to *state, 0
150         break $update-attributes:check-state
151       }
152       break $update-attributes:check-state
153     }
154   }
155 }
156 
157 fn clear toprow: int, leftcol: int, botrow: int, rightcol: int {
158   var row/ecx: int <- copy toprow
159   {
160     compare row, botrow
161     break-if->=
162     var col/edx: int <- copy leftcol
163     move-cursor 0, row, col
164     {
165       compare col, rightcol
166       break-if->=
167       print-string 0, " "
168       col <- increment
169       loop
170     }
171     row <- increment
172     loop
173   }
174 }
175 
176 fn dump in: (addr buffered-file) {
177   var c/eax: byte <- read-byte-buffered in
178   compare c, 0xffffffff  # EOF marker
179   break-if-=
180   var g/eax: grapheme <- copy c
181   print-grapheme 0, g
182   loop
183 }