1 ## compute the factorial of 5, and return the result in the exit code
  2 #
  3 # To run:
  4 #   $ ./subx translate 0*.subx apps/factorial.subx -o apps/factorial
  5 #   $ ./subx run apps/factorial
  6 # Expected result:
  7 #   $ echo $?
  8 #   120
  9 #
 10 # You can also run the automated test suite:
 11 #   $ ./subx run apps/factorial test
 12 # Expected output:
 13 #   ........
 14 # Every '.' indicates a passing test. Failing tests get a 'F'.
 15 
 16 == code
 17 #   instruction                     effective address                                                   register    displacement    immediate
 18 # . op          subop               mod             rm32          base        index         scale       r32
 19 # . 1-3 bytes   3 bits              2 bits          3 bits        3 bits      3 bits        2 bits      2 bits      0/1/2/4 bytes   0/1/2/4 bytes
 20 
 21 Entry:  # run tests if necessary, compute `factorial(5)` if not
 22     # . prolog
 23     89/copy                         3/mod/direct    5/rm32/ebp    .           .             .           4/r32/esp   .               .                 # copy esp to ebp
 24 
 25     # initialize heap
 26     # . Heap = new-segment(64KB)
 27     # . . push args
 28     68/push  Heap/imm32
 29     68/push  0x10000/imm32/64KB
 30     # . . call
 31     e8/call  new-segment/disp32
 32     # . . discard args
 33     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               8/imm32           # add to esp
 34 
 35     # - if argc > 1 and argv[1] == "test", then return run_tests()
 36     # if (argc <= 1) goto run-main
 37     81          7/subop/compare     1/mod/*+disp8   5/rm32/ebp    .           .             .           .           0/disp8         1/imm32           # compare *ebp
 38     7e/jump-if-lesser-or-equal  $run-main/disp8
 39     # if (!kernel-string-equal?(argv[1], "test")) goto run-main
 40     # . eax = kernel-string-equal?(argv[1], "test")
 41     # . . push args
 42     68/push  "test"/imm32
 43     ff          6/subop/push        1/mod/*+disp8   5/rm32/ebp    .           .             .           .           8/disp8         .                 # push *(ebp+8)
 44     # . . call
 45     e8/call  kernel-string-equal?/disp32
 46     # . . discard args
 47     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               8/imm32           # add to esp
 48     # . if (eax == 0) goto run-main
 49     3d/compare-eax-and  0/imm32
 50     74/jump-if-equal  $run-main/disp8
 51     # run-tests()
 52     e8/call  run-tests/disp32
 53     # return *Num-test-failures
 54     8b/copy                         0/mod/indirect  5/rm32/.disp32            .             .           3/r32/ebx   Num-test-failures/disp32          # copy *Num-test-failures to ebx
 55     eb/jump  $main:end/disp8
 56 $run-main:
 57     # - otherwise return factorial(5)
 58     # . . push args
 59     68/push  5/imm32
 60     # . . call
 61     e8/call  factorial/disp32
 62     # . . discard args
 63     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               4/imm32           # add to esp
 64     # syscall(exit, eax)
 65     89/copy                         3/mod/direct    3/rm32/ebx    .           .             .           0/r32/eax   .               .                 # copy eax to ebx
 66 $main:end:
 67     b8/copy-to-eax  1/imm32/exit
 68     cd/syscall  0x80/imm8
 69 
 70 factorial:  # n : int -> int/eax
 71     # . prolog
 72     55/push-ebp
 73     89/copy                         3/mod/direct    5/rm32/ebp    .           .             .           4/r32/esp   .               .                 # copy esp to ebp
 74     53/push-ebx
 75     # if (n <= 1) return 1
 76     b8/copy-to-eax  1/imm32
 77     81          7/subop/compare     1/mod/*+disp8   5/rm32/ebp    .           .             .           .           8/disp8         1/imm32           # compare *(ebp+8)
 78     7e/jump-if-<=  $factorial:end/disp8
 79     # ebx = n-1
 80     8b/copy                         1/mod/*+disp8   5/rm32/ebp    .           .                         3/r32/ebx   8/disp8         .                 # copy *(ebp+8) to ebx
 81     81          5/subop/subtract    3/mod/direct    3/rm32/ebx    .           .             .           .           .               1/imm32           # subtract from ebx
 82     # eax = factorial(n-1)
 83     # . . push args
 84     53/push-ebx
 85     # . . call
 86     e8/call  factorial/disp32
 87     # . . discard args
 88     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               4/imm32           # add to esp
 89     # return n * factorial(n-1)
 90     f7          4/subop/multiply    1/mod/*+disp8   5/rm32/ebp    .           .                                     8/disp8         .                 # multiply *(ebp+8) into eax
 91     # TODO: check for overflow
 92 $factorial:end:
 93     # . epilog
 94     5b/pop-to-ebx
 95     89/copy                         3/mod/direct    4/rm32/esp    .           .             .           5/r32/ebp   .               .                 # copy ebp to esp
 96     5d/pop-to-ebp
 97     c3/return
 98 
 99 test-factorial:
100     # factorial(5)
101     # . . push args
102     68/push  5/imm32
103     # . . call
104     e8/call  factorial/disp32
105     # . . discard args
106     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               4/imm32           # add to esp
107     # check-ints-equal(eax, 120, msg)
108     # . . push args
109     68/push  "F - test-factorial"/imm32
110     68/push  0x78/imm32/expected-120
111     50/push-eax
112     # . . call
113     e8/call  check-ints-equal/disp32
114     # . . discard args
115     81          0/subop/add         3/mod/direct    4/rm32/esp    .           .             .           .           .               0xc/imm32         # add to esp
116     # end
117     c3/return
118 
119 # . . vim:nowrap:textwidth=0