1 ## compute the factorial of 5, and return the result in the exit code
  2 #
  3 # Uses syntax sugar for:
  4 #   rm32 operands
  5 #
  6 # To run:
  7 #   $ ./translate_subx init.linux 0*.subx apps/factorial.subx -o apps/factorial
  8 #   $ ./bootstrap run apps/factorial
  9 # Expected result:
 10 #   $ echo $?
 11 #   120
 12 #
 13 # You can also run the automated test suite:
 14 #   $ ./bootstrap run apps/factorial test
 15 # Expected output:
 16 #   ........
 17 # Every '.' indicates a passing test. Failing tests get a 'F'.
 18 
 19 == code
 20 
 21 Entry:  # run tests if necessary, compute `factorial(5)` if not
 22     # . prologue
 23     89/<- %ebp 4/r32/esp
 24 
 25     # initialize heap
 26     # . Heap = new-segment(Heap-size)
 27     # . . push args
 28     68/push Heap/imm32
 29     ff 6/subop/push *Heap-size
 30     # . . call
 31     e8/call new-segment/disp32
 32     # . . discard args
 33     81 0/subop/add %esp 8/imm32
 34 
 35     # - if argc > 1 and argv[1] == "test", then return run_tests()
 36     # if (argc <= 1) goto run-main
 37     81 7/subop/compare *ebp 1/imm32
 38     7e/jump-if-<= $run-main/disp8
 39     # if (!kernel-string-equal?(argv[1], "test")) goto run-main
 40     # . eax = kernel-string-equal?(argv[1], "test")
 41     # . . push args
 42     68/push "test"/imm32
 43     ff 6/subop/push *(ebp+8)
 44     # . . call
 45     e8/call kernel-string-equal?/disp32
 46     # . . discard args
 47     81 0/subop/add %esp 8/imm32
 48     # . if (eax == false) goto run-main
 49     3d/compare-eax-and 0/imm32/false
 50     74/jump-if-= $run-main/disp8
 51     # run-tests()
 52     e8/call run-tests/disp32
 53     # syscall(exit, *Num-test-failures)
 54     8b/-> *Num-test-failures 3/r32/ebx
 55     eb/jump $main:end/disp8
 56 $run-main:
 57     # - otherwise return factorial(5)
 58     # eax = factorial(5)
 59     # . . push args
 60     68/push 5/imm32
 61     # . . call
 62     e8/call factorial/disp32
 63     # . . discard args
 64     81 0/subop/add %esp 4/imm32
 65     # syscall(exit, eax)
 66     89/<- %ebx 0/r32/eax
 67 $main:end:
 68     e8/call  syscall_exit/disp32
 69 
 70 factorial:  # n: int -> int/eax
 71     # . prologue
 72     55/push-ebp
 73     89/<- %ebp 4/r32/esp
 74     53/push-ebx
 75     # if (n <= 1) return 1
 76     b8/copy-to-eax 1/imm32
 77     81 7/subop/compare *(ebp+8) 1/imm32
 78     7e/jump-if-<= $factorial:end/disp8
 79     # var ebx: int = n-1
 80     8b/-> *(ebp+8) 3/r32/ebx
 81     4b/decrement-ebx
 82     # var eax: int = factorial(n-1)
 83     # . . push args
 84     53/push-ebx
 85     # . . call
 86     e8/call factorial/disp32
 87     # . . discard args
 88     81 0/subop/add %esp 4/imm32
 89     # return n * factorial(n-1)
 90     f7 4/subop/multiply-into-eax *(ebp+8)
 91     # TODO: check for overflow
 92 $factorial:end:
 93     # . epilogue
 94     5b/pop-to-ebx
 95     89/<- %esp 5/r32/ebp
 96     5d/pop-to-ebp
 97     c3/return
 98 
 99 test-factorial:
100     # factorial(5)
101     # . . push args
102     68/push 5/imm32
103     # . . call
104     e8/call factorial/disp32
105     # . . discard args
106     81 0/subop/add %esp 4/imm32
107     # check-ints-equal(eax, 120, msg)
108     # . . push args
109     68/push "F - test-factorial"/imm32
110     68/push 0x78/imm32/expected-120
111     50/push-eax
112     # . . call
113     e8/call check-ints-equal/disp32
114     # . . discard args
115     81 0/subop/add %esp 0xc/imm32
116     # end
117     c3/return