1 ## compute the factorial of 5, and return the result in the exit code
  2 #
  3 # Uses syntax sugar for:
  4 #   rm32 operands
  5 #
  6 # To run:
  7 #   $ ./translate_subx init.linux 0*.subx apps/factorial.subx -o apps/factorial
  8 #   $ ./bootstrap run apps/factorial
  9 # Expected result:
 10 #   $ echo $?
 11 #   120
 12 #
 13 # You can also run the automated test suite:
 14 #   $ ./bootstrap run apps/factorial test
 15 # Expected output:
 16 #   ........
 17 # Every '.' indicates a passing test. Failing tests get a 'F'.
 18 #
 19 # Compare apps/factorial.subx
 20 
 21 == code
 22 
 23 factorial:  # n: int -> int/eax
 24     # . prologue
 25     55/push-ebp
 26     89/<- %ebp 4/r32/esp
 27     53/push-ebx
 28     # if (n <= 1) return 1
 29     b8/copy-to-eax 1/imm32
 30     81 7/subop/compare *(ebp+8) 1/imm32
 31     7e/jump-if-<= $factorial:end/disp8
 32     # var ebx: int = n-1
 33     8b/-> *(ebp+8) 3/r32/ebx
 34     4b/decrement-ebx
 35     # var eax: int = factorial(n-1)
 36     # . . push args
 37     53/push-ebx
 38     # . . call
 39     e8/call factorial/disp32
 40     # . . discard args
 41     81 0/subop/add %esp 4/imm32
 42     # return n * factorial(n-1)
 43     f7 4/subop/multiply-into-eax *(ebp+8)
 44     # TODO: check for overflow
 45 $factorial:end:
 46     # . epilogue
 47     5b/pop-to-ebx
 48     89/<- %esp 5/r32/ebp
 49     5d/pop-to-ebp
 50     c3/return
 51 
 52 test-factorial:
 53     # factorial(5)
 54     # . . push args
 55     68/push 5/imm32
 56     # . . call
 57     e8/call factorial/disp32
 58     # . . discard args
 59     81 0/subop/add %esp 4/imm32
 60     # check-ints-equal(eax, 120, msg)
 61     # . . push args
 62     68/push "F - test-factorial"/imm32
 63     68/push 0x78/imm32/expected-120
 64     50/push-eax
 65     # . . call
 66     e8/call check-ints-equal/disp32
 67     # . . discard args
 68     81 0/subop/add %esp 0xc/imm32
 69     # end
 70     c3/return
 71 
 72 Entry:  # run tests if necessary, compute `factorial(5)` if not
 73     # . prologue
 74     89/<- %ebp 4/r32/esp
 75 
 76     # initialize heap
 77     # . Heap = new-segment(Heap-size)
 78     # . . push args
 79     68/push Heap/imm32
 80     ff 6/subop/push *Heap-size
 81     # . . call
 82     e8/call new-segment/disp32
 83     # . . discard args
 84     81 0/subop/add %esp 8/imm32
 85 
 86     # - if argc > 1 and argv[1] == "test", then return run_tests()
 87     # if (argc <= 1) goto run-main
 88     81 7/subop/compare *ebp 1/imm32
 89     7e/jump-if-<= $run-main/disp8
 90     # if (!kernel-string-equal?(argv[1], "test")) goto run-main
 91     # . eax = kernel-string-equal?(argv[1], "test")
 92     # . . push args
 93     68/push "test"/imm32
 94     ff 6/subop/push *(ebp+8)
 95     # . . call
 96     e8/call kernel-string-equal?/disp32
 97     # . . discard args
 98     81 0/subop/add %esp 8/imm32
 99     # . if (eax == false) goto run-main
100     3d/compare-eax-and 0/imm32/false
101     74/jump-if-= $run-main/disp8
102     # run-tests()
103     e8/call run-tests/disp32
104     # syscall(exit, *Num-test-failures)
105     8b/-> *Num-test-failures 3/r32/ebx
106     eb/jump $main:end/disp8
107 $run-main:
108     # - otherwise return factorial(5)
109     # ebx = factorial(5)
110     # . . push args
111     68/push 5/imm32
112     # . . call
113     e8/call factorial/disp32
114     # . . discard args
115     81 0/subop/add %esp 4/imm32
116     #
117     89/<- %ebx 0/r32/eax
118 $main:end:
119     e8/call  syscall_exit/disp32