1 ## compute the factorial of 5, and return the result in the exit code
 2 #
 3 # Uses syntax sugar for:
 4 #   rm32 operands
 5 #   function calls
 6 #
 7 # To run:
 8 #   $ ./translate_subx init.linux 0*.subx apps/factorial.subx -o apps/factorial
 9 #   $ ./bootstrap run apps/factorial
10 # Expected result:
11 #   $ echo $?
12 #   120
13 #
14 # You can also run the automated test suite:
15 #   $ ./bootstrap run apps/factorial test
16 # Expected output:
17 #   ........
18 # Every '.' indicates a passing test. Failing tests get a 'F'.
19 #
20 # Compare apps/factorial2.subx
21 
22 == code
23 
24 factorial:  # n: int -> int/eax
25     # . prologue
26     55/push-ebp
27     89/<- %ebp 4/r32/esp
28     # save registers
29     53/push-ebx
30     # if (n <= 1) return 1
31     b8/copy-to-eax 1/imm32
32     81 7/subop/compare *(ebp+8) 1/imm32
33     7e/jump-if-<= $factorial:end/disp8
34     # var ebx: int = n-1
35     8b/-> *(ebp+8) 3/r32/ebx
36     4b/decrement-ebx
37     #
38     (factorial %ebx)  # => eax
39     # return n * factorial(n-1)
40     f7 4/subop/multiply-into-eax *(ebp+8)
41     # TODO: check for overflow
42 $factorial:end:
43     # restore registers
44     5b/pop-to-ebx
45     # . epilogue
46     89/<- %esp 5/r32/ebp
47     5d/pop-to-ebp
48     c3/return
49 
50 test-factorial:
51     (factorial 5)
52     (check-ints-equal %eax 0x78 "F - test-factorial")
53     c3/return
54 
55 Entry:  # run tests if necessary, compute `factorial(5)` if not
56     # . prologue
57     89/<- %ebp 4/r32/esp
58 
59     # initialize heap (needed by tests elsewhere)
60     (new-segment *Heap-size Heap)
61 
62     # - if argc > 1 and argv[1] == "test", then return run_tests()
63     # if (argc <= 1) goto run-main
64     81 7/subop/compare *ebp 1/imm32
65     7e/jump-if-<= $run-main/disp8
66     # if (!kernel-string-equal?(argv[1], "test")) goto run-main
67     (kernel-string-equal? *(ebp+8) "test")  # => eax
68     # . if (eax == false) goto run-main
69     3d/compare-eax-and 0/imm32/false
70     74/jump-if-= $run-main/disp8
71     #
72     (run-tests)
73     # syscall(exit, *Num-test-failures)
74     8b/-> *Num-test-failures 3/r32/ebx
75     eb/jump $main:end/disp8
76 $run-main:
77     # - otherwise
78     (factorial 5)  # => eax
79     89/<- %ebx 0/r32/eax
80 $main:end:
81     e8/call  syscall_exit/disp32