1 ## compute the factorial of 5, and return the result in the exit code
 2 #
 3 # Uses syntax sugar for:
 4 #   rm32 operands
 5 #   function calls
 6 #
 7 # To run:
 8 #   $ ./translate_subx init.linux 0*.subx apps/factorial.subx -o apps/factorial
 9 #   $ ./bootstrap run apps/factorial
10 # Expected result:
11 #   $ echo $?
12 #   120
13 #
14 # You can also run the automated test suite:
15 #   $ ./bootstrap run apps/factorial test
16 # Expected output:
17 #   ........
18 # Every '.' indicates a passing test. Failing tests get a 'F'.
19 
20 == code
21 
22 Entry:  # run tests if necessary, compute `factorial(5)` if not
23     # . prologue
24     89/<- %ebp 4/r32/esp
25 
26     # initialize heap
27     (new-segment *Heap-size Heap)
28 
29     # - if argc > 1 and argv[1] == "test", then return run_tests()
30     # if (argc <= 1) goto run-main
31     81 7/subop/compare *ebp 1/imm32
32     7e/jump-if-<= $run-main/disp8
33     # if (!kernel-string-equal?(argv[1], "test")) goto run-main
34     (kernel-string-equal? *(ebp+8) "test")  # => eax
35     # . if (eax == false) goto run-main
36     3d/compare-eax-and 0/imm32/false
37     74/jump-if-= $run-main/disp8
38     #
39     (run-tests)
40     # syscall(exit, *Num-test-failures)
41     8b/-> *Num-test-failures 3/r32/ebx
42     eb/jump $main:end/disp8
43 $run-main:
44     # - otherwise
45     (factorial 5)  # => eax
46     # syscall(exit, eax)
47     89/<- %ebx 0/r32/eax
48 $main:end:
49     e8/call  syscall_exit/disp32
50 
51 factorial:  # n: int -> int/eax
52     # . prologue
53     55/push-ebp
54     89/<- %ebp 4/r32/esp
55     # save registers
56     53/push-ebx
57     # if (n <= 1) return 1
58     b8/copy-to-eax 1/imm32
59     81 7/subop/compare *(ebp+8) 1/imm32
60     7e/jump-if-<= $factorial:end/disp8
61     # var ebx: int = n-1
62     8b/-> *(ebp+8) 3/r32/ebx
63     4b/decrement-ebx
64     #
65     (factorial %ebx)  # => eax
66     # return n * factorial(n-1)
67     f7 4/subop/multiply-into-eax *(ebp+8)
68     # TODO: check for overflow
69 $factorial:end:
70     # restore registers
71     5b/pop-to-ebx
72     # . epilogue
73     89/<- %esp 5/r32/ebp
74     5d/pop-to-ebp
75     c3/return
76 
77 test-factorial:
78     (factorial 5)
79     (check-ints-equal %eax 0x78 "F - test-factorial")
80     c3/return