1 # Read a single byte from a stream.
 2 #
 3 # We need to do this in machine code because streams need to be opaque types,
 4 # and we don't yet support opaque types in Mu.
 5 
 6 == code
 7 #   instruction                     effective address                                                   register    displacement    immediate
 8 # . op          subop               mod             rm32          base        index         scale       r32
 9 # . 1-3 bytes   3 bits              2 bits          3 bits        3 bits      3 bits        2 bits      2 bits      0/1/2/4 bytes   0/1/2/4 bytes
10 
11 # Return next byte value in eax, with top 3 bytes cleared.
12 # Abort on reaching end of stream.
13 read-byte:  # s: (addr stream byte) -> result/eax: byte
14     # . prologue
15     55/push-ebp
16     89/copy                         3/mod/direct    5/rm32/ebp    .           .             .           4/r32/esp   .               .                 # copy esp to ebp
17     # . save registers
18     51/push-ecx
19     56/push-esi
20     # esi = s
21     8b/copy                         1/mod/*+disp8   5/rm32/ebp    .           .             .           6/r32/esi   8/disp8         .                 # copy *(ebp+8) to esi
22     # ecx = s->read
23     8b/copy                         1/mod/*+disp8   6/rm32/esi    .           .             .           1/r32/ecx   4/disp8         .                 # copy *(esi+4) to ecx
24     # if (f->read >= f->write) abort
25     3b/compare                      0/mod/indirect  6/rm32/esi    .           .             .           1/r32/ecx   .               .                 # compare ecx with *esi
26     0f 8d/jump-if->=  $read-byte:abort/disp32
27     # result = f->data[f->read]
28     31/xor                          3/mod/direct    0/rm32/eax    .           .             .           0/r32/eax   .               .                 # clear eax
29     8a/copy-byte                    1/mod/*+disp8   4/rm32/sib    6/base/esi  1/index/ecx   .           0/r32/AL    0xc/disp8       .                 # copy byte at *(esi+ecx+12) to AL
30     # ++f->read
31     ff          0/subop/increment   1/mod/*+disp8   6/rm32/esi    .           .             .           .           4/disp8         .                 # increment *(esi+4)
32 $read-byte:end:
33     # . restore registers
34     5e/pop-to-esi
35     59/pop-to-ecx
36     # . epilogue
37     89/copy                         3/mod/direct    4/rm32/esp    .           .             .           5/r32/ebp   .               .                 # copy ebp to esp
38     5d/pop-to-ebp
39     c3/return
40 
41 $read-byte:abort:
42     (draw-text-wrapping-right-then-down-from-cursor-over-full-screen 0 "read-byte: empty stream" 3)  # 3=cyan
43     {
44       eb/jump loop/disp8
45     }
46     # never gets here
47 
48 # . . vim:nowrap:textwidth=0