1 == code
 2 #   instruction                     effective address                                                   register    displacement    immediate
 3 # . op          subop               mod             rm32          base        index         scale       r32
 4 # . 1-3 bytes   3 bits              2 bits          3 bits        3 bits      3 bits        2 bits      2 bits      0/1/2/4 bytes   0/1/2/4 bytes
 5 
 6 # Write lower byte of 'n' to 'f'.
 7 append-byte:  # f: (addr stream byte), n: int
 8     # . prologue
 9     55/push-ebp
10     89/copy                         3/mod/direct    5/rm32/ebp    .           .             .           4/r32/esp   .               .                 # copy esp to ebp
11     # . save registers
12     51/push-ecx
13     57/push-edi
14     # edi = f
15     8b/copy                         1/mod/*+disp8   5/rm32/ebp    .           .             .           7/r32/edi   8/disp8         .                 # copy *(ebp+8) to edi
16     # ecx = f->write
17     8b/copy                         0/mod/indirect  7/rm32/edi    .           .             .           1/r32/ecx   .               .                 # copy *edi to ecx
18     # if (f->write >= f->size) abort
19     3b/compare                      1/mod/*+disp8   7/rm32/edi    .           .             .           1/r32/ecx   8/disp8         .                 # compare ecx with *(edi+8)
20     7d/jump-if->=  $append-byte:end/disp8  # TODO: abort
21 $append-byte:to-stream:
22     # write to stream
23     # f->data[f->write] = LSB(n)
24     31/xor                          3/mod/direct    0/rm32/eax    .           .             .           0/r32/eax   .               .                 # clear eax
25     8a/copy-byte                    1/mod/*+disp8   5/rm32/ebp    .           .             .           0/r32/AL    0xc/disp8       .                 # copy byte at *(ebp+12) to AL
26     88/copy-byte                    1/mod/*+disp8   4/rm32/sib    7/base/edi  1/index/ecx   .           0/r32/AL    0xc/disp8       .                 # copy AL to *(edi+ecx+12)
27     # ++f->write
28     ff          0/subop/increment   0/mod/indirect  7/rm32/edi    .           .             .           .           .               .                 # increment *edi
29 $append-byte:end:
30     # . restore registers
31     5f/pop-to-edi
32     59/pop-to-ecx
33     # . epilogue
34     89/copy                         3/mod/direct    4/rm32/esp    .           .             .           5/r32/ebp   .               .                 # copy ebp to esp
35     5d/pop-to-ebp
36     c3/return
37 
38 # . . vim:nowrap:textwidth=0