1 # _write: write to a file descriptor (fd)
 2 
 3 == code
 4 #   instruction                     effective address                                                   register    displacement    immediate
 5 # . op          subop               mod             rm32          base        index         scale       r32
 6 # . 1-3 bytes   3 bits              2 bits          3 bits        3 bits      3 bits        2 bits      2 bits      0/1/2/4 bytes   0/1/2/4 bytes
 7 
 8 #? Entry:  # just exit; can't test _write just yet
 9 #?     bb/copy-to-ebx  0/imm32
10 #?     e8/call  syscall_exit/disp32
11 
12 _write:  # fd: int, s: (addr array byte)
13     # . prologue
14     55/push-ebp
15     89/copy                         3/mod/direct    5/rm32/ebp    .           .             .           4/r32/esp   .               .                 # copy esp to ebp
16     # . save registers
17     50/push-eax
18     51/push-ecx
19     52/push-edx
20     53/push-ebx
21     # syscall_write(fd, (data) s+4, (size) *s)
22     # . ebx = fd
23     8b/copy                         1/mod/*+disp8   5/rm32/ebp    .           .             .           3/r32/ebx   8/disp8         .                 # copy *(ebp+8) to ebx
24     # . var data/ecx: (addr byte) = s+4
25     8b/copy                         1/mod/*+disp8   5/rm32/ebp    .           .             .           1/r32/ecx   0xc/disp8       .                 # copy *(ebp+12) to ecx
26     81          0/subop/add         3/mod/direct    1/rm32/ecx    .           .             .           .           .               4/imm32           # add to ecx
27     # . var size/edx: int = *s
28     8b/copy                         1/mod/*+disp8   5/rm32/ebp    .           .             .           2/r32/edx   0xc/disp8       .                 # copy *(ebp+12) to edx
29     8b/copy                         0/mod/indirect  2/rm32/edx    .           .             .           2/r32/edx   .               .                 # copy *edx to edx
30     # . syscall
31     e8/call  syscall_write/disp32
32     # if (eax < 0) abort
33     3d/compare-eax-with  0/imm32
34     0f 8c/jump-if-<  $_write:abort/disp32
35 $_write:end:
36     # . restore registers
37     5b/pop-to-ebx
38     5a/pop-to-edx
39     59/pop-to-ecx
40     58/pop-to-eax
41     # . epilogue
42     89/copy                         3/mod/direct    4/rm32/esp    .           .             .           5/r32/ebp   .               .                 # copy ebp to esp
43     5d/pop-to-ebp
44     c3/return
45 
46 $_write:abort:
47     # can't write a message here for risk of an infinite loop, so we'll use a special exit code instead
48     # . syscall_exit(255)
49     bb/copy-to-ebx  0xff/imm32
50     e8/call  syscall_exit/disp32
51     # never gets here
52 
53 # . . vim:nowrap:textwidth=0