1 # Comparing 'regular' length-prefixed strings.
  2 
  3 == code
  4 # instruction                     effective address                                                   operand     displacement    immediate
  5 # op          subop               mod             rm32          base        index         scale       r32
  6 # 1-3 bytes   3 bits              2 bits          3 bits        3 bits      3 bits        2 bits      2 bits      0/1/2/4 bytes   0/1/2/4 bytes
  7 
  8 # main:
  9   e8/call  run-tests/disp32  # 'run-tests' is a function created automatically by SubX. It calls all functions that start with 'test-'.
 10   # exit(Num-test-failures)
 11   8b/copy                         0/mod/indirect  5/rm32/.disp32            .             .           3/r32/EBX   Num-test-failures/disp32          # copy *Num-test-failures to EBX
 12   b8/copy-to-EAX  1/imm32
 13   cd/syscall  0x80/imm8
 14 
 15 string-equal:  # s : string, benchmark : string -> EAX : boolean
 16   # prolog
 17   55/push-EBP
 18   89/copy                         3/mod/direct    5/rm32/EBP    .           .             .           4/r32/ESP   .               .                 # copy ESP to EBP
 19   # save registers
 20   51/push-ECX
 21   52/push-EDX
 22   53/push-EBX
 23   56/push-ESI
 24   # pseudocode:
 25   #   if s.length != b.length return false
 26   #   for i = 0;  i < s.length;  ++i
 27   #     if s[i] != b[i] return false
 28   #   return true
 29   # registers:
 30   #   i: ECX
 31   #   s.length: EDX
 32   #   b.length: EBX
 33   #   b[i]: EBX
 34   #   s[i]: EAX
 35   #
 36   # var s/EAX : (address array byte)
 37   8b/copy                         1/mod/*+disp8   4/rm32/sib    5/base/EBP  4/index/none  .           0/r32/EAX   8/disp8         .                 # copy *(EBP+8) to EAX
 38   # var benchmark/EBX : (address array byte)
 39   8b/copy                         1/mod/*+disp8   4/rm32/sib    5/base/EBP  4/index/none  .           3/r32/EBX   0xc/disp8       .                 # copy *(EBP+12) to EBX
 40   # if s.length != b.length return false
 41     # EDX = s.length
 42   8b/copy                         0/mod/indirect  0/rm32/EAX    .           .             .           2/r32/EDX   .               .                 # copy *EAX to EDX
 43     # compare s.length and b.length
 44   39/compare                      0/mod/indirect  3/rm32/EBX    .           .             .           2/r32/EDX   .               .                 # compare *EBX with EDX
 45   75/jump-if-not-equal  $string-equal:false/disp8
 46 $string-equal:lengths:
 47   # var i/ECX : int = 0
 48   b9/copy-to-ECX  0/imm32
 49   # EBX = &b[i]
 50   43/inc-EBX
 51   # EAX = &s[i]
 52   40/inc-EAX
 53 $string-equal:loop:
 54   # if i >= s.length return true
 55   39/compare                      3/mod/direct    1/rm32/ECX    .           .             .           2/r32/EDX   .               .                 # compare ECX with EDX
 56   7d/jump-if-greater-or-equal  $string-equal:true/disp8
 57   # if b[i] != s[i] return false
 58     # ESI = s[i]
 59   8b/copy                         0/mod/indirect  0/rm32/EAX    .           .             .           6/r32/ESI   .               .                 # copy *EAX to ESI
 60     # compare b[i] with ESI
 61   39/compare                      0/mod/indirect  3/rm32/EBX    .           .             .           6/r32/ESI   .               .                 # compare *EBX with ESI
 62   75/jump-if-not-equal  $string-equal:false/disp8
 63   # ++i
 64   41/inc-ECX
 65   40/inc-EAX
 66   43/inc-EBX
 67   # loop
 68   eb/jump  $string-equal:loop/disp8
 69 $string-equal:true:
 70   # return true
 71   b8/copy-to-EAX  1/imm32
 72   eb/jump  $string-equal:end/disp8
 73 $string-equal:false:
 74   # return false
 75   b8/copy-to-EAX  0/imm32
 76 $string-equal:end:
 77   # restore registers
 78   5e/pop-to-ESI
 79   5b/pop-to-EBX
 80   5a/pop-to-EDX
 81   59/pop-to-ECX
 82   # epilog
 83   89/copy                         3/mod/direct    4/rm32/ESP    .           .             .           5/r32/EBP   .               .                 # copy EBP to ESP
 84   5d/pop-to-EBP
 85   c3/return
 86 
 87 ## tests
 88 
 89 test-compare-empty-with-empty-string:
 90   # EAX = string-equal("", "")
 91     # push args
 92   68/push  ""/imm32
 93   68/push  ""/imm32
 94     # call
 95   e8/call  string-equal/disp32
 96     # discard args
 97   81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               8/imm32           # add to ESP
 98   # call check-ints-equal(EAX, 1, msg)
 99     # push args
100   68/push  "F - test-compare-empty-with-empty-string"/imm32
101   68/push  1/imm32/true
102   50/push-EAX
103     # call
104   e8/call  check-ints-equal/disp32
105     # discard args
106   81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               0xc/imm32         # add to ESP
107   c3/return
108 
109 test-compare-empty-with-non-empty-string:  # also checks length-mismatch code path
110   # EAX = string-equal("", "Abc")
111     # push args
112   68/push  "Abc"/imm32
113   68/push  ""/imm32
114     # call
115   e8/call  string-equal/disp32
116     # discard args
117   81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               8/imm32           # add to ESP
118   # call check-ints-equal(EAX, 0, msg)
119     # push args
120   68/push  "F - test-compare-empty-with-non-empty-string"/imm32
121   68/push  0/imm32/false
122   50/push-EAX
123     # call
124   e8/call  check-ints-equal/disp32
125     # discard args
126   81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               0xc/imm32         # add to ESP
127   c3/return
128 
129 test-compare-equal-strings:
130   # EAX = string-equal("Abc", "Abc")
131     # push args
132   68/push  "Abc"/imm32
133   68/push  "Abc"/imm32
134     # call
135   e8/call  string-equal/disp32
136     # discard args
137   81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               8/imm32           # add to ESP
138   # call check-ints-equal(EAX, 1, msg)
139     # push args
140   68/push  "F - test-compare-equal-strings"/imm32
141   68/push  1/imm32/true
142   50/push-EAX
143     # call
144   e8/call  check-ints-equal/disp32
145     # discard args
146   81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               0xc/imm32         # add to ESP
147   c3/return
148 
149 test-compare-inequal-strings-equal-lengths:
150   # EAX = string-equal("Abc", "Adc")
151     # push args
152   68/push  "Adc"/imm32
153   68/push  "Abc"/imm32
154     # call
155   e8/call  string-equal/disp32
156     # discard args
157   81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               8/imm32           # add to ESP
158   # call check-ints-equal(EAX, 0, msg)
159     # push args
160   68/push  "F - test-compare-inequal-strings-equal-lengths"/imm32
161   68/push  0/imm32/false
162   50/push-EAX
163     # call
164   e8/call  check-ints-equal/disp32
165     # discard args
166   81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               0xc/imm32         # add to ESP
167   c3/return
168 
169 # vim:nowrap:textwidth=0