1 # write-buffered: like 'write', but for a buffered-file
  2 
  3 == code
  4 #   instruction                     effective address                                                   register    displacement    immediate
  5 # . op          subop               mod             rm32          base        index         scale       r32
  6 # . 1-3 bytes   3 bits              2 bits          3 bits        3 bits      3 bits        2 bits      2 bits      0/1/2/4 bytes   0/1/2/4 bytes
  7 
  8 # main:
  9 #?     e8/call test-write-buffered/disp32
 10 #?     e8/call test-write-buffered-with-intermediate-flush/disp32
 11     e8/call  run-tests/disp32  # 'run-tests' is a function created automatically by SubX. It calls all functions that start with 'test-'.
 12     # syscall(exit, Num-test-failures)
 13     8b/copy                         0/mod/indirect  5/rm32/.disp32            .             .           3/r32/EBX   Num-test-failures/disp32          # copy *Num-test-failures to EBX
 14     b8/copy-to-EAX  1/imm32/exit
 15     cd/syscall  0x80/imm8
 16 
 17 write-buffered:  # f : (address buffered-file), msg : (address array byte) -> <void>
 18     # pseudocode:
 19     #   in = msg->data
 20     #   inend = &msg->data[msg->length]
 21     #   while in < inend
 22     #     if f->write >= f->length
 23     #       flush(f)
 24     #       clear-stream(f)
 25     #     f->data[f->write] = *in
 26     #     ++f->write
 27     #     ++in
 28     #
 29     # registers:
 30     #   ESI : in
 31     #   ECX : inend
 32     #   EDI : f
 33     #   EDX : f->length
 34     #   EBX : f->write (cached copy, need to keep in sync)
 35     #   EAX : temp
 36     #
 37     # . prolog
 38     55/push-EBP
 39     89/copy                         3/mod/direct    5/rm32/EBP    .           .             .           4/r32/ESP   .               .                 # copy ESP to EBP
 40     # . save registers
 41     50/push-EAX
 42     51/push-ECX
 43     52/push-EDX
 44     53/push-EBX
 45     56/push-ESI
 46     57/push-EDI
 47     # EAX = msg
 48     8b/copy                         1/mod/*+disp8   5/rm32/EBP    .           .                         0/r32/EAX   0xc/disp8       .                 # copy *(EBP+12) to EAX
 49     # in/ESI = msg->data
 50     8d/copy-address                 1/mod/*+disp8   0/rm32/EAX    .           .             .           6/r32/ESI   4/disp8         .                 # copy EAX+4 to ESI
 51     # inend/ECX = &msg->data[msg->length]
 52     8b/copy                         0/mod/indirect  0/rm32/EAX    .           .             .           1/r32/ECX   .               .                 # copy *EAX to ECX
 53     8d/copy-address                 0/mod/indirect  4/rm32/sib    6/base/ESI  1/index/ECX   .           1/r32/ECX   .               .                 # copy ESI+ECX to ECX
 54     # EDI = f
 55     8b/copy                         1/mod/*+disp8   5/rm32/EBP    .           .                         7/r32/EDI   8/disp8         .                 # copy *(EBP+8) to EDI
 56     # EDX = f->length
 57     8b/copy                         1/mod/*+disp8   7/rm32/EDI    .           .             .           2/r32/EDX   0xc/disp8       .                 # copy *(EDI+12) to EDX
 58     # EBX = f->write
 59     8b/copy                         1/mod/*+disp8   7/rm32/EDI    .           .             .           3/r32/EBX   4/disp8         .                 # copy *(EDI+4) to EBX
 60 $write-buffered:loop:
 61     # if (in >= inend) break
 62     39/compare                      3/mod/direct    6/rm32/ESI    .           .             .           1/r32/ECX   .               .                 # compare ESI with ECX
 63     7d/jump-if-greater-or-equal  $write-buffered:loop-end/disp8
 64     # if (f->write >= f->length) flush and clear f's stream
 65     39/compare                      3/mod/direct    3/rm32/EBX    .           .             .           2/r32/EDX   .               .                 # compare EBX with EDX
 66     7c/jump-if-lesser  $write-buffered:to-stream/disp8
 67     # . persist f->write
 68     89/copy                         1/mod/*+disp8   7/rm32/EDI    .           .             .           3/r32/EBX   4/disp8         .                 # copy EBX to *(EDI+4)
 69     # . flush(f)
 70     # . . push args
 71     57/push-EDI
 72     # . . call
 73     e8/call  flush/disp32
 74     # . . discard args
 75     81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               4/imm32           # add to ESP
 76     # . clear-stream(stream = f+4)
 77     # . . push args
 78     8d/copy-address                 1/mod/*+disp8   7/rm32/EDI    .           .             .           0/r32/EAX   4/disp8         .                 # copy EDI+4 to EAX
 79     50/push-EAX
 80     # . . call
 81     e8/call  clear-stream/disp32
 82     # . . discard args
 83     81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               4/imm32           # add to ESP
 84     # . clear EBX (cached f->write)
 85     31/xor                          3/mod/direct    3/rm32/EBX    .           .             .           3/r32/EBX   .               .                 # clear EBX
 86 $write-buffered:to-stream:
 87     # write to stream
 88     # f->data[f->write] = *in
 89     # . AL = *in
 90     31/xor                          3/mod/direct    0/rm32/EAX    .           .             .           0/r32/EAX   .               .                 # clear EAX
 91     8a/copy-byte                    0/mod/indirect  6/rm32/ESI    .           .             .           0/r32/AL    .               .                 # copy byte at *ESI to AL
 92     # . f->data[f->write] = AL
 93     88/copy-byte                    1/mod/*+disp8   4/rm32/sib    7/base/EDI  3/index/EBX   .           0/r32/AL    0x10/disp8      .                 # copy AL to *(EDI+EBX+16)
 94     # ++f->write
 95     43/increment-EBX
 96     # ++in
 97     46/increment-ESI
 98     eb/jump  $write-buffered:loop/disp8
 99 $write-buffered:loop-end:
100     # persist necessary variables from registers
101     89/copy                         1/mod/*+disp8   7/rm32/EDI    .           .             .           3/r32/EBX   4/disp8         .                 # copy EBX to *(EDI+4)
102 $write-buffered:end:
103     # . restore registers
104     5f/pop-to-EDI
105     5e/pop-to-ESI
106     5b/pop-to-EBX
107     5a/pop-to-EDX
108     59/pop-to-ECX
109     58/pop-to-EAX
110     # . epilog
111     89/copy                         3/mod/direct    4/rm32/ESP    .           .             .           5/r32/EBP   .               .                 # copy EBP to ESP
112     5d/pop-to-EBP
113     c3/return
114 
115 test-write-buffered:
116     # - check that write-buffered writes to the file
117     # setup
118     # . clear-stream(_test-stream)
119     # . . push args
120     68/push  _test-stream/imm32
121     # . . call
122     e8/call  clear-stream/disp32
123     # . . discard args
124     81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               4/imm32           # add to ESP
125     # . clear-stream(_test-buffered-file+4)
126     # . . push args
127     b8/copy-to-EAX  _test-buffered-file/imm32
128     05/add-to-EAX  4/imm32
129     50/push-EAX
130     # . . call
131     e8/call  clear-stream/disp32
132     # . . discard args
133     81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               4/imm32           # add to ESP
134     # write-buffered(_test-buffered-file, "Abc")
135     # . . push args
136     68/push  "Abc"/imm32
137     68/push  _test-buffered-file/imm32
138     # . . call
139     e8/call  write-buffered/disp32
140     # . . discard args
141     81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               8/imm32           # add to ESP
142     # flush(_test-buffered-file)
143     # . . push args
144     68/push  _test-buffered-file/imm32
145     # . . call
146     e8/call  flush/disp32
147     # . . discard args
148     81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               4/imm32           # add to ESP
149     # check-ints-equal(*_test-stream->data, "Abc", msg)
150     # . . push args
151     68/push  "F - test-write-buffered-single"/imm32
152     68/push  0x636241/imm32
153     # . . push *_test-stream->data
154     b8/copy-to-EAX  _test-stream/imm32
155     ff          6/subop/push        1/mod/*+disp8   0/rm32/EAX    .           .             .           .           0xc/disp8       .                 # push *(EAX+12)
156     # . . call
157     e8/call  check-ints-equal/disp32
158     # . . discard args
159     81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               0xc/imm32         # add to ESP
160     # . end
161     c3/return
162 
163 test-write-buffered-with-intermediate-flush:
164     # - check that write-buffered flushes in the middle if its buffer fills up
165     # setup
166     # . clear-stream(_test-stream)
167     # . . push args
168     68/push  _test-stream/imm32
169     # . . call
170     e8/call  clear-stream/disp32
171     # . . discard args
172     81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               4/imm32           # add to ESP
173     # . clear-stream(_test-buffered-file+4)
174     # . . push args
175     b8/copy-to-EAX  _test-buffered-file/imm32
176     05/add-to-EAX  4/imm32
177     50/push-EAX
178     # . . call
179     e8/call  clear-stream/disp32
180     # . . discard args
181     81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               4/imm32           # add to ESP
182     # _test-stream can hold 8 bytes, but _test-buffered-file can hold only 6.
183     # Try to write 7 bytes.
184     # . write-buffered(_test-buffered-file, "Abcdefg")
185     # . . push args
186     68/push  "Abcdefg"/imm32
187     68/push  _test-buffered-file/imm32
188     # . . call
189     e8/call  write-buffered/disp32
190     # . . discard args
191     81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               8/imm32           # add to ESP
192     # don't flush
193     # 6 bytes should still have gotten to _test-stream
194     # . check-ints-equal(*_test-stream->write, 6, msg)
195     # . . push args
196     68/push  "F - test-write-buffered-with-intermediate-flush: flushed data"/imm32
197     68/push  6/imm32
198     # . . push *_test-stream->write
199     b8/copy-to-EAX  _test-stream/imm32
200     ff          6/subop/push        0/mod/indirect  0/rm32/EAX    .           .             .           .           .               .                 # push *EAX
201     # . . call
202     e8/call  check-ints-equal/disp32
203     # . . discard args
204     81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               0xc/imm32         # add to ESP
205     # and 1 byte should still be in _test-buffered-file
206     # . check-ints-equal(*_test-buffered-file>write, 1, msg)
207     # . . push args
208     68/push  "F - test-write-buffered-with-intermediate-flush: unflushed bytes"/imm32
209     68/push  1/imm32
210     # . . push *_test-buffered-file->write
211     b8/copy-to-EAX  _test-buffered-file/imm32
212     ff          6/subop/push        1/mod/*+disp8   0/rm32/EAX    .           .             .           .           4/disp8         .                 # push *(EAX+4)
213     # . . call
214     e8/call  check-ints-equal/disp32
215     # . . discard args
216     81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               0xc/imm32         # add to ESP
217     # . end
218     c3/return
219 
220 # . . vim:nowrap:textwidth=0