1 # write-buffered: like 'write', but for a buffered-file
  2 
  3 == code
  4 #   instruction                     effective address                                                   register    displacement    immediate
  5 # . op          subop               mod             rm32          base        index         scale       r32
  6 # . 1-3 bytes   3 bits              2 bits          3 bits        3 bits      3 bits        2 bits      2 bits      0/1/2/4 bytes   0/1/2/4 bytes
  7 
  8 write-buffered:  # f : (address buffered-file), msg : (address array byte) -> <void>
  9     # pseudocode:
 10     #   in = msg->data
 11     #   inend = &msg->data[msg->length]
 12     #   while (in < inend)
 13     #     if f->write >= f->length
 14     #       flush(f)
 15     #       clear-stream(f)
 16     #     c = *in
 17     #     f->data[f->write] = c
 18     #     ++f->write
 19     #     ++in
 20     #
 21     # registers:
 22     #   in: ESI
 23     #   inend: ECX
 24     #   f: EDI
 25     #   f->length: EDX
 26     #   f->write: EBX (cached; need to keep in sync)
 27     #   c: EAX
 28     #
 29     # . prolog
 30     55/push-EBP
 31     89/copy                         3/mod/direct    5/rm32/EBP    .           .             .           4/r32/ESP   .               .                 # copy ESP to EBP
 32     # . save registers
 33     50/push-EAX
 34     51/push-ECX
 35     52/push-EDX
 36     53/push-EBX
 37     56/push-ESI
 38     57/push-EDI
 39     # EAX = msg
 40     8b/copy                         1/mod/*+disp8   5/rm32/EBP    .           .                         0/r32/EAX   0xc/disp8       .                 # copy *(EBP+12) to EAX
 41     # in/ESI = msg->data
 42     8d/copy-address                 1/mod/*+disp8   0/rm32/EAX    .           .             .           6/r32/ESI   4/disp8         .                 # copy EAX+4 to ESI
 43     # inend/ECX = &msg->data[msg->length]
 44     8b/copy                         0/mod/indirect  0/rm32/EAX    .           .             .           1/r32/ECX   .               .                 # copy *EAX to ECX
 45     8d/copy-address                 0/mod/indirect  4/rm32/sib    6/base/ESI  1/index/ECX   .           1/r32/ECX   .               .                 # copy ESI+ECX to ECX
 46     # EDI = f
 47     8b/copy                         1/mod/*+disp8   5/rm32/EBP    .           .                         7/r32/EDI   8/disp8         .                 # copy *(EBP+8) to EDI
 48     # EDX = f->length
 49     8b/copy                         1/mod/*+disp8   7/rm32/EDI    .           .             .           2/r32/EDX   0xc/disp8       .                 # copy *(EDI+12) to EDX
 50     # EBX = f->write
 51     8b/copy                         1/mod/*+disp8   7/rm32/EDI    .           .             .           3/r32/EBX   4/disp8         .                 # copy *(EDI+4) to EBX
 52 $write-buffered:loop:
 53     # if (in >= inend) break
 54     39/compare                      3/mod/direct    6/rm32/ESI    .           .             .           1/r32/ECX   .               .                 # compare ESI with ECX
 55     73/jump-if-greater-or-equal-unsigned  $write-buffered:loop-end/disp8
 56     # if (f->write >= f->length) flush and clear f's stream
 57     39/compare                      3/mod/direct    3/rm32/EBX    .           .             .           2/r32/EDX   .               .                 # compare EBX with EDX
 58     7c/jump-if-lesser  $write-buffered:to-stream/disp8
 59     # . persist f->write
 60     89/copy                         1/mod/*+disp8   7/rm32/EDI    .           .             .           3/r32/EBX   4/disp8         .                 # copy EBX to *(EDI+4)
 61     # . flush(f)
 62     # . . push args
 63     57/push-EDI
 64     # . . call
 65     e8/call  flush/disp32
 66     # . . discard args
 67     81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               4/imm32           # add to ESP
 68     # . clear-stream(stream = f+4)
 69     # . . push args
 70     8d/copy-address                 1/mod/*+disp8   7/rm32/EDI    .           .             .           0/r32/EAX   4/disp8         .                 # copy EDI+4 to EAX
 71     50/push-EAX
 72     # . . call
 73     e8/call  clear-stream/disp32
 74     # . . discard args
 75     81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               4/imm32           # add to ESP
 76     # . f->write must now be 0; update its cache at EBX
 77     31/xor                          3/mod/direct    3/rm32/EBX    .           .             .           3/r32/EBX   .               .                 # clear EBX
 78 $write-buffered:to-stream:
 79     # write to stream
 80     # f->data[f->write] = *in
 81     # . AL = *in
 82     31/xor                          3/mod/direct    0/rm32/EAX    .           .             .           0/r32/EAX   .               .                 # clear EAX
 83     8a/copy-byte                    0/mod/indirect  6/rm32/ESI    .           .             .           0/r32/AL    .               .                 # copy byte at *ESI to AL
 84     # . f->data[f->write] = AL
 85     88/copy-byte                    1/mod/*+disp8   4/rm32/sib    7/base/EDI  3/index/EBX   .           0/r32/AL    0x10/disp8      .                 # copy AL to *(EDI+EBX+16)
 86     # ++f->write
 87     43/increment-EBX
 88     # ++in
 89     46/increment-ESI
 90     eb/jump  $write-buffered:loop/disp8
 91 $write-buffered:loop-end:
 92     # persist necessary variables from registers
 93     89/copy                         1/mod/*+disp8   7/rm32/EDI    .           .             .           3/r32/EBX   4/disp8         .                 # copy EBX to *(EDI+4)
 94 $write-buffered:end:
 95     # . restore registers
 96     5f/pop-to-EDI
 97     5e/pop-to-ESI
 98     5b/pop-to-EBX
 99     5a/pop-to-EDX
100     59/pop-to-ECX
101     58/pop-to-EAX
102     # . epilog
103     89/copy                         3/mod/direct    4/rm32/ESP    .           .             .           5/r32/EBP   .               .                 # copy EBP to ESP
104     5d/pop-to-EBP
105     c3/return
106 
107 test-write-buffered:
108     # - check that write-buffered writes to the file
109     # setup
110     # . clear-stream(_test-stream)
111     # . . push args
112     68/push  _test-stream/imm32
113     # . . call
114     e8/call  clear-stream/disp32
115     # . . discard args
116     81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               4/imm32           # add to ESP
117     # . clear-stream(_test-buffered-file+4)
118     # . . push args
119     b8/copy-to-EAX  _test-buffered-file/imm32
120     05/add-to-EAX  4/imm32
121     50/push-EAX
122     # . . call
123     e8/call  clear-stream/disp32
124     # . . discard args
125     81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               4/imm32           # add to ESP
126     # write-buffered(_test-buffered-file, "Abc")
127     # . . push args
128     68/push  "Abc"/imm32
129     68/push  _test-buffered-file/imm32
130     # . . call
131     e8/call  write-buffered/disp32
132     # . . discard args
133     81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               8/imm32           # add to ESP
134     # flush(_test-buffered-file)
135     # . . push args
136     68/push  _test-buffered-file/imm32
137     # . . call
138     e8/call  flush/disp32
139     # . . discard args
140     81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               4/imm32           # add to ESP
141     # check-stream-equal(_test-stream, "Abc", msg)
142     # . . push args
143     68/push  "F - test-write-buffered-single"/imm32
144     68/push  "Abc"/imm32
145     68/push  _test-stream/imm32
146     # . . call
147     e8/call  check-stream-equal/disp32
148     # . . discard args
149     81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               0xc/imm32         # add to ESP
150     # . end
151     c3/return
152 
153 test-write-buffered-with-intermediate-flush:
154     # - check that write-buffered flushes in the middle if its buffer fills up
155     # setup
156     # . clear-stream(_test-stream)
157     # . . push args
158     68/push  _test-stream/imm32
159     # . . call
160     e8/call  clear-stream/disp32
161     # . . discard args
162     81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               4/imm32           # add to ESP
163     # . clear-stream(_test-buffered-file+4)
164     # . . push args
165     b8/copy-to-EAX  _test-buffered-file/imm32
166     05/add-to-EAX  4/imm32
167     50/push-EAX
168     # . . call
169     e8/call  clear-stream/disp32
170     # . . discard args
171     81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               4/imm32           # add to ESP
172     # _test-stream can hold 8 bytes, but _test-buffered-file can hold only 6.
173     # Try to write 7 bytes.
174     # . write-buffered(_test-buffered-file, "Abcdefg")
175     # . . push args
176     68/push  "Abcdefg"/imm32
177     68/push  _test-buffered-file/imm32
178     # . . call
179     e8/call  write-buffered/disp32
180     # . . discard args
181     81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               8/imm32           # add to ESP
182     # don't flush
183     # 6 bytes should still have gotten to _test-stream
184     # . check-ints-equal(*_test-stream->write, 6, msg)
185     # . . push args
186     68/push  "F - test-write-buffered-with-intermediate-flush: flushed data"/imm32
187     68/push  6/imm32
188     # . . push *_test-stream->write
189     b8/copy-to-EAX  _test-stream/imm32
190     ff          6/subop/push        0/mod/indirect  0/rm32/EAX    .           .             .           .           .               .                 # push *EAX
191     # . . call
192     e8/call  check-ints-equal/disp32
193     # . . discard args
194     81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               0xc/imm32         # add to ESP
195     # and 1 byte should still be in _test-buffered-file
196     # . check-ints-equal(*_test-buffered-file->write, 1, msg)
197     # . . push args
198     68/push  "F - test-write-buffered-with-intermediate-flush: unflushed bytes"/imm32
199     68/push  1/imm32
200     # . . push *_test-buffered-file->write
201     b8/copy-to-EAX  _test-buffered-file/imm32
202     ff          6/subop/push        1/mod/*+disp8   0/rm32/EAX    .           .             .           .           4/disp8         .                 # push *(EAX+4)
203     # . . call
204     e8/call  check-ints-equal/disp32
205     # . . discard args
206     81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               0xc/imm32         # add to ESP
207     # . end
208     c3/return
209 
210 # . . vim:nowrap:textwidth=0