1 ## compute the factorial of 5, and return the result in the exit code
  2 #
  3 # To run (from the subx directory):
  4 #   $ ./subx translate apps/factorial.subx -o apps/factorial
  5 #   $ ./subx run apps/factorial
  6 # Expected result:
  7 #   $ echo $?
  8 #   120
  9 #
 10 # You can also run the automated test suite:
 11 #   $ ./subx run apps/factorial test
 12 # Expected output:
 13 #   ........
 14 # Every '.' indicates a passing test. Failing tests get a 'F'.
 15 
 16 == code
 17 #   instruction                     effective address                                                   register    displacement    immediate
 18 # . op          subop               mod             rm32          base        index         scale       r32
 19 # . 1-3 bytes   3 bits              2 bits          3 bits        3 bits      3 bits        2 bits      2 bits      0/1/2/4 bytes   0/1/2/4 bytes
 20 
 21 # main:
 22     # . prolog
 23     89/copy                         3/mod/direct    5/rm32/EBP    .           .             .           4/r32/ESP   .               .                 # copy ESP to EBP
 24     # - if argc > 1 and argv[1] == "test" then return run_tests()
 25     # . argc > 1
 26     81          7/subop/compare     1/mod/*+disp8   5/rm32/EBP    .           .             .           .           0/disp8         1/imm32           # compare *EBP
 27     7e/jump-if-lesser-or-equal  $run-main/disp8
 28     # . argv[1] == "test"
 29     # . . push args
 30     68/push  "test"/imm32
 31     ff          6/subop/push        1/mod/*+disp8   5/rm32/EBP    .           .             .           .           8/disp8         .                 # push *(EBP+8)
 32     # . . call
 33     e8/call  kernel-string-equal?/disp32
 34     # . . discard args
 35     81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               8/imm32           # add to ESP
 36     # . check result
 37     3d/compare-EAX  1/imm32
 38     75/jump-if-not-equal  $run-main/disp8
 39     # . run-tests()
 40     e8/call  run-tests/disp32
 41     8b/copy                         0/mod/indirect  5/rm32/.disp32            .             .           0/r32/EAX   Num-test-failures/disp32          # copy *Num-test-failures to EAX
 42     eb/jump  $main:end/disp8  # where EAX will get copied to EBX
 43     # - otherwise return factorial(5)
 44 $run-main:
 45     # . . push args
 46     68/push  5/imm32
 47     # . . call
 48     e8/call  factorial/disp32
 49     # . . discard args
 50     81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               4/imm32           # add to ESP
 51 $main:end:
 52     # syscall(exit, EAX)
 53     89/copy                         3/mod/direct    3/rm32/EBX    .           .             .           0/r32/EAX   .               .                 # copy EAX to EBX
 54     b8/copy-to-EAX  1/imm32/exit
 55     cd/syscall  0x80/imm8
 56 
 57 factorial:  # n : int -> int/EAX
 58     # . prolog
 59     55/push-EBP
 60     89/copy                         3/mod/direct    5/rm32/EBP    .           .             .           4/r32/ESP   .               .                 # copy ESP to EBP
 61     53/push-EBX
 62     # EAX = 1 (base case)
 63     b8/copy-to-EAX  1/imm32
 64     # if (n <= 1) return
 65     81          7/subop/compare     1/mod/*+disp8   5/rm32/EBP    .           .             .           .           8/disp8         1/imm32           # compare *(EBP+8)
 66     7e/jump-if-<=  $factorial:end/disp8
 67     # EBX = n-1
 68     8b/copy                         1/mod/*+disp8   5/rm32/EBP    .           .                         3/r32/EBX   8/disp8         .                 # copy *(EBP+8) to EBX
 69     81          5/subop/subtract    3/mod/direct    3/rm32/EBX    .           .             .           .           .               1/imm32           # subtract from EBX
 70     # EAX = factorial(n-1)
 71     # . . push args
 72     53/push-EBX
 73     # . . call
 74     e8/call  factorial/disp32
 75     # . . discard args
 76     81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               4/imm32           # add to ESP
 77     # return n * factorial(n-1)
 78     f7          4/subop/multiply    1/mod/*+disp8   5/rm32/EBP    .           .                                     8/disp8         .                 # multiply *(EBP+8) into EAX
 79     # TODO: check for overflow
 80 $factorial:end:
 81     # . epilog
 82     5b/pop-to-EBX
 83     89/copy                         3/mod/direct    4/rm32/ESP    .           .             .           5/r32/EBP   .               .                 # copy EBP to ESP
 84     5d/pop-to-EBP
 85     c3/return
 86 
 87 test-factorial:
 88     # factorial(5)
 89     # . . push args
 90     68/push  5/imm32
 91     # . . call
 92     e8/call  factorial/disp32
 93     # . . discard args
 94     81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               4/imm32           # add to ESP
 95     # check-ints-equal(EAX, 120, msg)
 96     # . . push args
 97     68/push  "F - test-factorial"/imm32
 98     68/push  0x78/imm32/expected-120
 99     50/push-EAX
100     # . . call
101     e8/call  check-ints-equal/disp32
102     # . . discard args
103     81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               0xc/imm32         # add to ESP
104     # end
105     c3/return
106 
107 # . . vim:nowrap:textwidth=0