1 ## compute the factorial of 5, and return the result in the exit code
  2 #
  3 # To run (from the subx directory):
  4 #   $ ./subx translate apps/factorial.subx -o apps/factorial
  5 #   $ ./subx run apps/factorial
  6 # Expected result:
  7 #   $ echo $?
  8 #   120
  9 #
 10 # You can also run the automated test suite:
 11 #   $ ./subx run apps/factorial test
 12 # Expected output:
 13 #   ........
 14 # Every '.' indicates a passing test. Failing tests get a 'F'.
 15 # When running tests the exit status doesn't mean anything. Yet.
 16 
 17 == code
 18 #   instruction                     effective address                                                   register    displacement    immediate
 19 # . op          subop               mod             rm32          base        index         scale       r32
 20 # . 1-3 bytes   3 bits              2 bits          3 bits        3 bits      3 bits        2 bits      2 bits      0/1/2/4 bytes   0/1/2/4 bytes
 21 
 22 # main:
 23     # . prolog
 24     89/copy                         3/mod/direct    5/rm32/EBP    .           .             .           4/r32/ESP   .               .                 # copy ESP to EBP
 25     # - if argc > 1 and argv[1] == "test" then return run_tests()
 26     # . argc > 1
 27     81          7/subop/compare     1/mod/*+disp8   5/rm32/EBP    .           .             .           .           0/disp8         1/imm32           # compare *EBP
 28     7e/jump-if-lesser-or-equal  $run-main/disp8
 29     # . argv[1] == "test"
 30     # . . push args
 31     68/push  "test"/imm32
 32     ff          6/subop/push        1/mod/*+disp8   5/rm32/EBP    .           .             .           .           8/disp8         .                 # push *(EBP+8)
 33     # . . call
 34     e8/call  kernel-string-equal/disp32
 35     # . . discard args
 36     81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               8/imm32           # add to ESP
 37     # . check result
 38     3d/compare-EAX  1/imm32
 39     75/jump-if-not-equal  $run-main/disp8
 40     # . run-tests()
 41     e8/call  run-tests/disp32
 42     8b/copy                         0/mod/indirect  5/rm32/.disp32            .             .           0/r32/EAX   Num-test-failures/disp32          # copy *Num-test-failures to EAX
 43     eb/jump  $main:end/disp8  # where EAX will get copied to EBX
 44     # - otherwise return factorial(5)
 45 $run-main:
 46     # . . push args
 47     68/push  5/imm32
 48     # . . call
 49     e8/call  factorial/disp32
 50     # . . discard args
 51     81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               4/imm32           # add to ESP
 52 $main:end:
 53     # syscall(exit, EAX)
 54     89/copy                         3/mod/direct    3/rm32/EBX    .           .             .           0/r32/EAX   .               .                 # copy EAX to EBX
 55     b8/copy-to-EAX  1/imm32/exit
 56     cd/syscall  0x80/imm8
 57 
 58 factorial:  # n : int -> int/EAX
 59     # . prolog
 60     55/push-EBP
 61     89/copy                         3/mod/direct    5/rm32/EBP    .           .             .           4/r32/ESP   .               .                 # copy ESP to EBP
 62     53/push-EBX
 63     # EAX = 1 (base case)
 64     b8/copy-to-EAX  1/imm32
 65     # if (n <= 1) return
 66     81          7/subop/compare     1/mod/*+disp8   5/rm32/EBP    .           .             .           .           8/disp8         1/imm32           # compare *(EBP+8)
 67     7e/jump-if-<=  $factorial:end/disp8
 68     # EBX = n-1
 69     8b/copy                         1/mod/*+disp8   5/rm32/EBP    .           .                         3/r32/EBX   8/disp8         .                 # copy *(EBP+8) to EBX
 70     81          5/subop/subtract    3/mod/direct    3/rm32/EBX    .           .             .           .           .               1/imm32           # subtract from EBX
 71     # EAX = factorial(n-1)
 72     # . . push args
 73     53/push-EBX
 74     # . . call
 75     e8/call  factorial/disp32
 76     # . . discard args
 77     81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               4/imm32           # add to ESP
 78     # return n * factorial(n-1)
 79     f7          4/subop/multiply    1/mod/*+disp8   5/rm32/EBP    .           .                                     8/disp8         .                 # multiply *(EBP+8) into EAX
 80     # TODO: check for overflow
 81 $factorial:end:
 82     # . epilog
 83     5b/pop-to-EBX
 84     89/copy                         3/mod/direct    4/rm32/ESP    .           .             .           5/r32/EBP   .               .                 # copy EBP to ESP
 85     5d/pop-to-EBP
 86     c3/return
 87 
 88 test-factorial:
 89     # factorial(5)
 90     # . . push args
 91     68/push  5/imm32
 92     # . . call
 93     e8/call  factorial/disp32
 94     # . . discard args
 95     81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               4/imm32           # add to ESP
 96     # check-ints-equal(EAX, 120, msg)
 97     # . . push args
 98     68/push  "F - test-factorial"/imm32
 99     68/push  0x78/imm32/expected-120
100     50/push-EAX
101     # . . call
102     e8/call  check-ints-equal/disp32
103     # . . discard args
104     81          0/subop/add         3/mod/direct    4/rm32/ESP    .           .             .           .           .               0xc/imm32         # add to ESP
105     # end
106     c3/return
107 
108 # . . vim:nowrap:textwidth=0