Nim - This repository contains the Nim compiler, Nim's stdlib, tools, and documentation. (mirror)

diff options
Diffstat (limited to 'lib/impure')
0 files changed, 0 insertions, 0 deletions
='n45' href='#n45'>45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395
## the 'copy' button makes it easy to duplicate a sandbox, and thence to
## see code operate in multiple situations

scenario copy-a-sandbox-to-editor [
  local-scope
  trace-until 100/app  # trace too long
  assume-screen 100/width, 10/height
  # empty recipes
  assume-resources [
  ]
  env:&:environment <- new-programming-environment resources, screen, [add 1, 1]  # contents of sandbox editor
  render-all screen, env, render
  # run it
  assume-console [
    press F4
  ]
  event-loop screen, console, env, resources
  screen-should-contain [
    .                                                                                 run (F4)           .
    .                                                  ┊                                                 .
    .┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┊─────────────────────────────────────────────────.
    .                                                  ┊0   edit       copy       to recipe    delete    .
    .                                                  ┊add 1, 1                                         .
    .                                                  ┊2                                                .
    .                                                  ┊─────────────────────────────────────────────────.
    .                                                  ┊                                                 .
  ]
  # click at left edge of 'copy' button
  assume-console [
    left-click 3, 69
  ]
  run [
    event-loop screen, console, env, resources
  ]
  # it copies into editor
  screen-should-contain [
    .                                                                                 run (F4)           .
    .                                                  ┊add 1, 1                                         .
    .┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┊─────────────────────────────────────────────────.
    .                                                  ┊0   edit       copy       to recipe    delete    .
    .                                                  ┊add 1, 1                                         .
    .                                                  ┊2                                                .
    .                                                  ┊─────────────────────────────────────────────────.
    .                                                  ┊                                                 .
  ]
  # cursor should be in the right place
  assume-console [
    type [0]
  ]
  run [
    event-loop screen, console, env, resources
  ]
  screen-should-contain [
    .                                                                                 run (F4)           .
    .                                                  ┊0add 1, 1                                        .
    .┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┊─────────────────────────────────────────────────.
    .                                                  ┊0   edit       copy       to recipe    delete    .
    .                                                  ┊add 1, 1                                         .
    .                                                  ┊2                                                .
    .                                                  ┊─────────────────────────────────────────────────.
    .                                                  ┊                                                 .
  ]
]

scenario copy-a-sandbox-to-editor-2 [
  local-scope
  trace-until 100/app  # trace too long
  assume-screen 100/width, 10/height
  # empty recipes
  assume-resources [
  ]
  env:&:environment <- new-programming-environment resources, screen, [add 1, 1]  # contents of sandbox editor
  render-all screen, env, render
  # run it
  assume-console [
    press F4
  ]
  event-loop screen, console, env, resources
  screen-should-contain [
    .                                                                                 run (F4)           .
    .                                                  ┊                                                 .
    .┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┊─────────────────────────────────────────────────.
    .                                                  ┊0   edit       copy       to recipe    delete    .
    .                                                  ┊add 1, 1                                         .
    .                                                  ┊2                                                .
    .                                                  ┊─────────────────────────────────────────────────.
    .                                                  ┊                                                 .
  ]
  # click at right edge of 'copy' button (just before 'delete')
  assume-console [
    left-click 3, 76
  ]
  run [
    event-loop screen, console, env, resources
  ]
  # it copies into editor
  screen-should-contain [
    .                                                                                 run (F4)           .
    .                                                  ┊add 1, 1                                         .
    .┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┊─────────────────────────────────────────────────.
    .                                                  ┊0   edit       copy       to recipe    delete    .
    .                                                  ┊add 1, 1                                         .
    .                                                  ┊2                                                .
    .                                                  ┊─────────────────────────────────────────────────.
    .                                                  ┊                                                 .
  ]
  # cursor should be in the right place
  assume-console [
    type [0]
  ]
  run [
    event-loop screen, console, env, resources
  ]
  screen-should-contain [
    .                                                                                 run (F4)           .
    .                                                  ┊0add 1, 1                                        .
    .┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┊─────────────────────────────────────────────────.
    .                                                  ┊0   edit       copy       to recipe    delete    .
    .                                                  ┊add 1, 1                                         .
    .                                                  ┊2                                                .
    .                                                  ┊─────────────────────────────────────────────────.
    .                                                  ┊                                                 .
  ]
]

after <global-touch> [
  # support 'copy' button
  {
    copy?:bool <- should-attempt-copy? click-row, click-column, env
    break-unless copy?
    copy?, env <- try-copy-sandbox click-row, env
    break-unless copy?
    screen <- render-sandbox-side screen, env, render
    screen <- update-cursor screen, recipes, current-sandbox, sandbox-in-focus?, env
    loop +next-event
  }
]

# some preconditions for attempting to copy a sandbox
def should-attempt-copy? click-row:num, click-column:num, env:&:environment -> result:bool [
  local-scope
  load-inputs
  # are we below the sandbox editor?
  click-sandbox-area?:bool <- click-on-sandbox-area? click-row, click-column, env
  return-unless click-sandbox-area?, 0/false
  # narrower, is the click in the columns spanning the 'copy' button?
  first-sandbox:&:editor <- get *env, current-sandbox:offset
  assert first-sandbox, [!!]
  sandbox-left-margin:num <- get *first-sandbox, left:offset
  sandbox-right-margin:num <- get *first-sandbox, right:offset
  _, _, copy-button-left:num, copy-button-right:num <- sandbox-menu-columns sandbox-left-margin, sandbox-right-margin
  copy-button-vertical-area?:bool <- within-range? click-column, copy-button-left, copy-button-right
  return-unless copy-button-vertical-area?, 0/false
  # finally, is sandbox editor empty?
  current-sandbox:&:editor <- get *env, current-sandbox:offset
  result <- empty-editor? current-sandbox
]

def try-copy-sandbox click-row:num, env:&:environment -> clicked-on-copy-button?:bool, env:&:environment [
  local-scope
  load-inputs
  # identify the sandbox to copy, if the click was actually on the 'copy' button
  sandbox:&:sandbox <- find-sandbox env, click-row
  return-unless sandbox, 0/false
  clicked-on-copy-button? <- copy 1/true
  text:text <- get *sandbox, data:offset
  current-sandbox:&:editor <- get *env, current-sandbox:offset
  current-sandbox <- insert-text current-sandbox, text
  # reset scroll
  *env <- put *env, render-from:offset, -1
  # position cursor in sandbox editor
  *env <- put *env, sandbox-in-focus?:offset, 1/true
]

def find-sandbox env:&:environment, click-row:num -> result:&:sandbox [
  local-scope
  load-inputs
  curr-sandbox:&:sandbox <- get *env, sandbox:offset
  {
    break-unless curr-sandbox
    start:num <- get *curr-sandbox, starting-row-on-screen:offset
    found?:bool <- equal click-row, start
    return-if found?, curr-sandbox
    curr-sandbox <- get *curr-sandbox, next-sandbox:offset
    loop
  }
  return 0/not-found
]

def click-on-sandbox-area? click-row:num, click-column:num, env:&:environment -> result:bool [
  local-scope
  load-inputs
  current-sandbox:&:editor <- get *env, current-sandbox:offset
  sandbox-left-margin:num <- get *current-sandbox, left:offset
  on-sandbox-side?:bool <- greater-or-equal click-column, sandbox-left-margin
  return-unless on-sandbox-side?, 0/false
  first-sandbox:&:sandbox <- get *env, sandbox:offset
  return-unless first-sandbox, 0/false
  first-sandbox-begins:num <- get *first-sandbox, starting-row-on-screen:offset
  result <- greater-or-equal click-row, first-sandbox-begins
]

def empty-editor? editor:&:editor -> result:bool [
  local-scope
  load-inputs
  head:&:duplex-list:char <- get *editor, data:offset
  first:&:duplex-list:char <- next head
  result <- not first
]

def within-range? x:num, low:num, high:num -> result:bool [
  local-scope
  load-inputs
  not-too-far-left?:bool <- greater-or-equal x, low
  not-too-far-right?:bool <- lesser-or-equal x, high
  result <- and not-too-far-left? not-too-far-right?
]

scenario copy-fails-if-sandbox-editor-not-empty [
  local-scope
  trace-until 100/app  # trace too long
  assume-screen 100/width, 10/height
  # empty recipes
  assume-resources [
  ]
  env:&:environment <- new-programming-environment resources, screen, [add 1, 1]  # contents of sandbox editor
  render-all screen, env, render
  # run it
  assume-console [
    press F4
  ]
  event-loop screen, console, env, resources
  screen-should-contain [
    .                                                                                 run (F4)           .
    .                                                  ┊                                                 .
    .┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┊─────────────────────────────────────────────────.
    .                                                  ┊0   edit       copy       to recipe    delete    .
    .                                                  ┊add 1, 1                                         .
    .                                                  ┊2                                                .
    .                                                  ┊─────────────────────────────────────────────────.
    .                                                  ┊                                                 .
  ]
  # type something into the sandbox editor, then click on the 'copy' button
  assume-console [
    left-click 2, 70  # put cursor in sandbox editor
    type [0]  # type something
    left-click 3, 70  # click 'copy' button
  ]
  run [
    event-loop screen, console, env, resources
  ]
  # copy doesn't happen
  screen-should-contain [
    .                                                                                 run (F4)           .
    .                                                  ┊0                                                .
    .┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┊─────────────────────────────────────────────────.
    .                                                  ┊0   edit       copy       to recipe    delete    .
    .                                                  ┊add 1, 1                                         .
    .                                                  ┊2                                                .
    .                                                  ┊─────────────────────────────────────────────────.
    .                                                  ┊                                                 .
  ]
  # cursor should be in the right place
  assume-console [
    type [1]
  ]
  run [
    event-loop screen, console, env, resources
  ]
  screen-should-contain [
    .                                                                                 run (F4)           .
    .                                                  ┊01                                               .
    .┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┊─────────────────────────────────────────────────.
    .                                                  ┊0   edit       copy       to recipe    delete    .
    .                                                  ┊add 1, 1                                         .
    .                                                  ┊2                                                .
    .                                                  ┊─────────────────────────────────────────────────.
    .                                                  ┊                                                 .
  ]
]

## the 'to recipe' button makes it easy to create a function out of a sandbox

scenario copy-a-sandbox-to-recipe-side [
  local-scope
  trace-until 100/app  # trace too long
  assume-screen 100/width, 10/height
  # empty recipes
  assume-resources [
  ]
  env:&:environment <- new-programming-environment resources, screen, [add 1, 1]  # contents of sandbox editor
  render-all screen, env, render
  # run it
  assume-console [
    press F4
  ]
  event-loop screen, console, env, resources
  screen-should-contain [
    .                                                                                 run (F4)           .
    .                                                  ┊                                                 .
    .┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┊─────────────────────────────────────────────────.
    .                                                  ┊0   edit       copy       to recipe    delete    .
    .                                                  ┊add 1, 1                                         .
    .                                                  ┊2                                                .
    .                                                  ┊─────────────────────────────────────────────────.
    .                                                  ┊                                                 .
  ]
  # click at left edge of 'copy' button
  assume-console [
    left-click 3, 78
  ]
  run [
    event-loop screen, console, env, resources
  ]
  # it copies into recipe side
  screen-should-contain [
    .                                                                                 run (F4)           .
    .add 1, 1                                          ┊                                                 .
    .                                                  ┊─────────────────────────────────────────────────.
    .                                                  ┊0   edit       copy       to recipe    delete    .
    .┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┊add 1, 1                                         .
    .                                                  ┊2                                                .
    .                                                  ┊─────────────────────────────────────────────────.
    .                                                  ┊                                                 .
  ]
  # cursor should be at the top left of the recipe side
  assume-console [
    type [0]
  ]
  run [
    event-loop screen, console, env, resources
  ]
  screen-should-contain [
    .                                                                                 run (F4)           .
    .0add 1, 1                                         ┊                                                 .
    .                                                  ┊─────────────────────────────────────────────────.
    .                                                  ┊0   edit       copy       to recipe    delete    .
    .┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┊add 1, 1                                         .
    .                                                  ┊2                                                .
    .                                                  ┊─────────────────────────────────────────────────.
    .                                                  ┊                                                 .
  ]
]

after <global-touch> [
  # support 'copy to recipe' button
  {
    copy?:bool <- should-copy-to-recipe? click-row, click-column, env
    break-unless copy?
    modified?:bool <- prepend-sandbox-into-recipe-side click-row, env
    break-unless modified?
    *env <- put *env, sandbox-in-focus?:offset, 0/false
    screen <- render-recipes screen, env, render
    screen <- update-cursor screen, recipes, current-sandbox, sandbox-in-focus?, env
    loop +next-event
  }
]

# some preconditions for attempting to copy a sandbox into the recipe side
def should-copy-to-recipe? click-row:num, click-column:num, env:&:environment -> result:bool [
  local-scope
  load-inputs
  # are we below the sandbox editor?
  click-sandbox-area?:bool <- click-on-sandbox-area? click-row, click-column, env
  return-unless click-sandbox-area?, 0/false
  # narrower, is the click in the columns spanning the 'copy' button?
  first-sandbox:&:editor <- get *env, current-sandbox:offset
  assert first-sandbox, [!!]
  sandbox-left-margin:num <- get *first-sandbox, left:offset
  sandbox-right-margin:num <- get *first-sandbox, right:offset
  _, _, _, _, recipe-button-left:num, recipe-button-right:num <- sandbox-menu-columns sandbox-left-margin, sandbox-right-margin
  result <- within-range? click-column, recipe-button-left, recipe-button-right
]

def prepend-sandbox-into-recipe-side click-row:num, env:&:environment -> clicked-on-copy-to-recipe-button?:bool, env:&:environment [
  local-scope
  load-inputs
  sandbox:&:sandbox <- find-sandbox env, click-row
  return-unless sandbox, 0/false
  recipe-editor:&:editor <- get *env, recipes:offset
  recipe-data:&:duplex-list:char <- get *recipe-editor, data:offset
  # make the newly inserted code easy to delineate
  newline:char <- copy 10
  insert newline, recipe-data
  insert newline, recipe-data
  # insert code from the selected sandbox
  sandbox-data:text <- get *sandbox, data:offset
  insert recipe-data, sandbox-data
  # reset cursor
  *recipe-editor <- put *recipe-editor, top-of-screen:offset, recipe-data
  *recipe-editor <- put *recipe-editor, before-cursor:offset, recipe-data
  *recipe-editor <- put *recipe-editor, cursor-row:offset, 1
  *recipe-editor <- put *recipe-editor, cursor-column:offset, 0
  return 1/true
]

context:
space:
mode: