blob: ef2262ec0ed106a39155041397b2f4ab476119e1 (
plain) (
tree)
|
|
## compute the factorial of 5, and return the result in the exit code
#
# To run:
# $ ./subx translate init.linux 0*.subx apps/factorial.subx -o apps/factorial
# $ ./subx run apps/factorial
# Expected result:
# $ echo $?
# 120
#
# You can also run the automated test suite:
# $ ./subx run apps/factorial test
# Expected output:
# ........
# Every '.' indicates a passing test. Failing tests get a 'F'.
== code
# instruction effective address register displacement immediate
# . op subop mod rm32 base index scale r32
# . 1-3 bytes 3 bits 2 bits 3 bits 3 bits 3 bits 2 bits 2 bits 0/1/2/4 bytes 0/1/2/4 bytes
Entry: # run tests if necessary, compute `factorial(5)` if not
# . prolog
89/copy 3/mod/direct 5/rm32/ebp . . . 4/r32/esp . . # copy esp to ebp
# initialize heap
# . Heap = new-segment(Heap-size)
# . . push args
68/push Heap/imm32
68/push Heap-size/imm32
# . . call
e8/call new-segment/disp32
# . . discard args
81 0/subop/add 3/mod/direct 4/rm32/esp . . . . . 8/imm32 # add to esp
# - if argc > 1 and argv[1] == "test", then return run_tests()
# if (argc <= 1) goto run-main
81 7/subop/compare 1/mod/*+disp8 5/rm32/ebp . . . . 0/disp8 1/imm32 # compare *ebp
7e/jump-if-lesser-or-equal $run-main/disp8
# if (!kernel-string-equal?(argv[1], "test")) goto run-main
# . eax = kernel-string-equal?(argv[1], "test")
# . . push args
68/push "test"/imm32
ff 6/subop/push 1/mod/*+disp8 5/rm32/ebp . . . . 8/disp8 . # push *(ebp+8)
# . . call
e8/call kernel-string-equal?/disp32
# . . discard args
81 0/subop/add 3/mod/direct 4/rm32/esp . . . . . 8/imm32 # add to esp
# . if (eax == 0) goto run-main
3d/compare-eax-and 0/imm32
74/jump-if-equal $run-main/disp8
# run-tests()
e8/call run-tests/disp32
# syscall(exit, *Num-test-failures)
8b/copy 0/mod/indirect 5/rm32/.disp32 . . 3/r32/ebx Num-test-failures/disp32 # copy *Num-test-failures to ebx
eb/jump $main:end/disp8
$run-main:
# - otherwise return factorial(5)
# eax = factorial(5)
# . . push args
68/push 5/imm32
# . . call
e8/call factorial/disp32
# . . discard args
81 0/subop/add 3/mod/direct 4/rm32/esp . . . . . 4/imm32 # add to esp
# syscall(exit, eax)
89/copy 3/mod/direct 3/rm32/ebx . . . 0/r32/eax . . # copy eax to ebx
$main:end:
b8/copy-to-eax 1/imm32/exit
cd/syscall 0x80/imm8
factorial: # n : int -> int/eax
# . prolog
55/push-ebp
89/copy 3/mod/direct 5/rm32/ebp . . . 4/r32/esp . . # copy esp to ebp
53/push-ebx
# if (n <= 1) return 1
b8/copy-to-eax 1/imm32
81 7/subop/compare 1/mod/*+disp8 5/rm32/ebp . . . . 8/disp8 1/imm32 # compare *(ebp+8)
7e/jump-if-<= $factorial:end/disp8
# ebx = n-1
8b/copy 1/mod/*+disp8 5/rm32/ebp . . 3/r32/ebx 8/disp8 . # copy *(ebp+8) to ebx
81 5/subop/subtract 3/mod/direct 3/rm32/ebx . . . . . 1/imm32 # subtract from ebx
# eax = factorial(n-1)
# . . push args
53/push-ebx
# . . call
e8/call factorial/disp32
# . . discard args
81 0/subop/add 3/mod/direct 4/rm32/esp . . . . . 4/imm32 # add to esp
# return n * factorial(n-1)
f7 4/subop/multiply 1/mod/*+disp8 5/rm32/ebp . . 8/disp8 . # multiply *(ebp+8) into eax
# TODO: check for overflow
$factorial:end:
# . epilog
5b/pop-to-ebx
89/copy 3/mod/direct 4/rm32/esp . . . 5/r32/ebp . . # copy ebp to esp
5d/pop-to-ebp
c3/return
test-factorial:
# factorial(5)
# . . push args
68/push 5/imm32
# . . call
e8/call factorial/disp32
# . . discard args
81 0/subop/add 3/mod/direct 4/rm32/esp . . . . . 4/imm32 # add to esp
# check-ints-equal(eax, 120, msg)
# . . push args
68/push "F - test-factorial"/imm32
68/push 0x78/imm32/expected-120
50/push-eax
# . . call
e8/call check-ints-equal/disp32
# . . discard args
81 0/subop/add 3/mod/direct 4/rm32/esp . . . . . 0xc/imm32 # add to esp
# end
c3/return
# . . vim:nowrap:textwidth=0
|