|
|
# Helper to print an int32 in decimal.
== code
# instruction effective address register displacement immediate
# . op subop mod rm32 base index scale r32
# . 1-3 bytes 3 bits 2 bits 3 bits 3 bits 3 bits 2 bits 2 bits 0/1/2/4 bytes 0/1/2/4 bytes
#? Entry: # run a single test, while debugging
#? e8/call test-print-int32-decimal-negative/disp32
#?
#? # syscall(exit, Num-test-failures)
#? 8b/copy 0/mod/indirect 5/rm32/.disp32 . . 3/r32/EBX Num-test-failures/disp32 # copy *Num-test-failures to EBX
#? b8/copy-to-EAX 1/imm32/exit
#? cd/syscall 0x80/imm8
print-int32-decimal: # out : (address stream), n : int32
# PSEUDOCODE
# based on K&R itoa: https://en.wikibooks.org/wiki/C_Programming/stdlib.h/itoa
# push SENTINAL
# if n >= 0:
# goto digit-encode
# else:
# n = -n
# negative = true
# while true:
# push n % 10 + '0'
# n = n / 10
# break if n == 0
# if negative:
# push '-'
# while true:
# EAX = pop
# break if EAX == SENTINAL
# out->data[out->write++] = EAX
#
# . prolog
55/push-EBP
89/copy 3/mod/direct 5/rm32/EBP . . . 4/r32/ESP . . # copy ESP to EBP
# . save registers
50/push-EAX
51/push-ECX
52/push-EDX
53/push-EBX
57/push-EDI
# negative = false
bf/copy-to-EDI 0/imm32 # EDI = 0
# push sentinal for $append-loop
68/push-sentinel 0/imm32
# EAX = n
8b/copy 1/mod/*+disp8 5/rm32/EBP . . . 0/r32/EAX 0xc/disp8 . # EAX = *(EBP+12)
# if n >= 0 jump to digit-encode
3d/compare-EAX-and 0/imm32
7d/jump-if-greater-eq $digit-encode:prelude/disp8
# else
# n = -n
f7 3/subop/negate 3/mod/direct 0/rm32/EAX # EAX = -EAX
# negative = true
bf/copy-to-EDI 1/imm32 # EDI = 1
$digit-encode:prelude:
# EBX = n
8b/copy 3/mod/direct 0/rm32/EAX . . . 3/r32/EBX . . # EBX = EAX
$digit-encode-loop:
# EAX = EBX(n)
89/copy 3/mod/direct 0/rm32/EAX . . . 3/r32/EBX . . # EAX = EBX
b9/copy-to-ECX 0xa/imm32
99/sign-extend-EAX-into-EDX
# EDX:EAX(n) / ECX(10)
# EDX, EAX = n % 10, n / 10
f7 7/subop/idiv 3/mod/direct 1/rm32/ECX . . . . . . # divide EDX:EAX by ECX, storing quotient in EAX and remainder in EDX
81 0/subop/add 3/mod/direct 2/rm32/EDX . . . . . 0x30/imm32 # EDX += '0' (0x30)
# push n % 10 + '0'
52/push-EDX
# EBX = n / 10
89/copy 3/mod/direct 3/rm32/EBX . . . 0/r32/EAX . . # EBX = EAX
# loop if n / 10 > 0
3d/compare-EAX-and 0/imm32
7f/jump-if-greater $digit-encode-loop/disp8
# else:
8b/copy 3/mod/direct 7/rm32/EDI . . . 0/r32/EAX . . # EAX = EDX
# . if !negative: goto append-loop
3d/compare-EAX-and 0/imm32
74/jump-if-equal $append-loop:prelude/disp8
# . else
68/push-negative 0x2d/imm32 # push '-'
$append-loop:prelude:
# EBX = &out
8b/copy 1/mod/*+disp8 5/rm32/EBP . . . 3/r32/EBX 8/disp8 . # copy *(EBP+8) to EBX
$append-loop:
# EAX = next_character
58/pop-to-EAX
3d/compare-EAX . . . . . . . 0/imm32 # EAX == 0
74/jump-if-equal $append-loop:break/disp8
# ECX = out->write
8b/copy 0/mod/indirect 3/rm32/EBX . . . 1/r32/ECX . . # ECX = *EBX
# out->data[out->write] = next_character
# . ECX = &out->data[out->write]
8d/copy-address 1/mod/*+disp8 4/rm32/sib 3/base/EBX 1/index/ECX . 1/r32/ECX 0xc/disp8 . # copy EBX+ECX+12 to ECX
# . out->data[out->write] = EAX
89/copy 0/mod/indirect 1/rm32/ECX . . . 0/r32/ECX . . # *ECX = EAX
# out->write++
ff 0/subop/increment 0/mod/indirect 3/rm32/EBX . . . . . . # (*EBX)++
eb/jump $append-loop/disp8
$append-loop:break:
$print-int32-decimal:end:
# . reclaim locals
# . restore registers
57/pop-to-EDI
5b/pop-to-EBX
5a/pop-to-EDX
59/pop-to-ECX
58/pop-to-EAX
# . epilog
89/copy 3/mod/direct 4/rm32/ESP . . . 5/r32/EBP . . # copy EBP to ESP
5d/pop-to-EBP
c3/return
$print-int32-decimal:abort:
# . _write(2/stderr, error)
# . . push args
68/push "print-int32-decimal: out of space"/imm32
68/push 2/imm32/stderr
# . . call
e8/call _write/disp32
# . . discard args
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 8/imm32 # add to ESP
# . syscall(exit, 1)
bb/copy-to-EBX 1/imm32
b8/copy-to-EAX 1/imm32/exit
cd/syscall 0x80/imm8
# never gets here
test-print-int32-decimal:
# - check that a single-digit number converts correctly
# setup
# . clear-stream(_test-stream)
# . . push args
68/push _test-stream/imm32
# . . call
e8/call clear-stream/disp32
# . . discard args
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 4/imm32 # add to ESP
# print-int32-decimal(_test-stream, 9)
# . . push args
68/push 9/imm32
68/push _test-stream/imm32
# . . call
e8/call print-int32-decimal/disp32
# . . discard args
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 8/imm32 # add to ESP
# check-stream-equal(_test-stream, "9", msg)
# . . push args
68/push "F - test-print-int32-decimal"/imm32
68/push "9"/imm32
68/push _test-stream/imm32
# . . call
e8/call check-stream-equal/disp32
# . . discard args
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 0xc/imm32 # add to ESP
# . end
c3/return
test-print-int32-decimal-zero:
# - check that 0 converts correctly
# setup
# . clear-stream(_test-stream)
# . . push args
68/push _test-stream/imm32
# . . call
e8/call clear-stream/disp32
# . . discard args
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 4/imm32 # add to ESP
# print-int32-decimal(_test-stream, 0)
# . . push args
68/push 0/imm32
68/push _test-stream/imm32
# . . call
e8/call print-int32-decimal/disp32
# . . discard args
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 8/imm32 # add to ESP
# check-stream-equal(_test-stream, "0", msg)
# . . push args
68/push "F - test-print-int32-decimal-zero"/imm32
68/push "0"/imm32
68/push _test-stream/imm32
# . . call
e8/call check-stream-equal/disp32
# . . discard args
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 0xc/imm32 # add to ESP
# . end
c3/return
test-print-int32-decimal-multiple-digits:
# - check that a multi-digit number converts correctly
# setup
# . clear-stream(_test-stream)
# . . push args
68/push _test-stream/imm32
# . . call
e8/call clear-stream/disp32
# . . discard args
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 4/imm32 # add to ESP
# print-int32-decimal(_test-stream, 10)
# . . push args
68/push 0xa/imm32
68/push _test-stream/imm32
# . . call
e8/call print-int32-decimal/disp32
# . . discard args
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 8/imm32 # add to ESP
# check-stream-equal(_test-stream, "10", msg)
# . . push args
68/push "F - test-print-int32-decimal-multiple-digits"/imm32
68/push "10"/imm32
68/push _test-stream/imm32
# . . call
e8/call check-stream-equal/disp32
# . . discard args
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 0xc/imm32 # add to ESP
# . end
c3/return
test-print-int32-decimal-negative:
# - check that a negative single-digit number converts correctly
# setup
# . clear-stream(_test-stream)
# . . push args
68/push _test-stream/imm32
# . . call
e8/call clear-stream/disp32
# . . discard args
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 4/imm32 # add to ESP
# print-int32-decimal(_test-stream, -9)
# . . push args
68/push -9/imm32
68/push _test-stream/imm32
# . . call
e8/call print-int32-decimal/disp32
# . . discard args
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 8/imm32 # add to ESP
#? # dump _test-stream {{{
#? # . write(2/stderr, "^")
#? # . . push args
#? 68/push "^"/imm32
#? 68/push 2/imm32/stderr
#? # . . call
#? e8/call write/disp32
#? # . . discard args
#? 81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 8/imm32 # add to ESP
#? # . write-stream(2/stderr, _test-stream)
#? # . . push args
#? 68/push _test-stream/imm32
#? 68/push 2/imm32/stderr
#? # . . call
#? e8/call write-stream/disp32
#? # . . discard args
#? 81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 8/imm32 # add to ESP
#? # . write(2/stderr, "$\n")
#? # . . push args
#? 68/push "$\n"/imm32
#? 68/push 2/imm32/stderr
#? # . . call
#? e8/call write/disp32
#? # . . discard args
#? 81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 8/imm32 # add to ESP
#? # }}}
# check-stream-equal(_test-stream, "-9", msg)
# . . push args
68/push "F - test-print-int32-decimal-negative"/imm32
68/push "-9"/imm32
68/push _test-stream/imm32
# . . call
e8/call check-stream-equal/disp32
# . . discard args
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 0xc/imm32 # add to ESP
# . end
c3/return
test-print-int32-decimal-negative-multiple-digits:
# - check that a multi-digit number converts correctly
# setup
# . clear-stream(_test-stream)
# . . push args
68/push _test-stream/imm32
# . . call
e8/call clear-stream/disp32
# . . discard args
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 4/imm32 # add to ESP
# print-int32-decimal(_test-stream, -10)
# . . push args
68/push -0xa/imm32
68/push _test-stream/imm32
# . . call
e8/call print-int32-decimal/disp32
# . . discard args
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 8/imm32 # add to ESP
# check-stream-equal(_test-stream, "-10", msg)
# . . push args
68/push "F - test-print-int32-decimal-negative-multiple-digits"/imm32
68/push "-10"/imm32
68/push _test-stream/imm32
# . . call
e8/call check-stream-equal/disp32
# . . discard args
81 0/subop/add 3/mod/direct 4/rm32/ESP . . . . . 0xc/imm32 # add to ESP
# . end
c3/return
# . . vim:nowrap:textwidth=0
|