mu - Soul of a tiny new machine. More thorough tests → More comprehensible and rewrite-friendly software → More resilient society.

	Commit message (Expand)	Author	Age	Files	Lines
*	6397	Kartik Agaram	2020-05-24	1	-0/+362

# new type to help incrementally read texts (arrays of characters)
container stream [
  index:number
  data:address:shared:array:character
]

recipe new-stream s:address:shared:array:character -> result:address:shared:stream [
  local-scope
  load-ingredients
  result <- new stream:type
  i:address:number <- get-address *result, index:offset
  *i <- copy 0
  d:address:address:shared:array:character <- get-address *result, data:offset
  *d <- copy s
]

recipe rewind-stream in:address:shared:stream -> in:address:shared:stream [
  local-scope
  load-ingredients
  x:address:number <- get-address *in, index:offset
  *x <- copy 0
]

recipe read-line in:address:shared:stream -> result:address:shared:array:character, in:address:shared:stream [
  local-scope
  load-ingredients
  idx:address:number <- get-address *in, index:offset
  s:address:shared:array:character <- get *in, data:offset
  next-idx:number <- find-next s, 10/newline, *idx
  result <- copy-range s, *idx, next-idx
  *idx <- add next-idx, 1  # skip newline
]

recipe end-of-stream? in:address:shared:stream -> result:boolean [
  local-scope
  load-ingredients
  idx:number <- get *in, index:offset
  s:address:shared:array:character <- get *in, data:offset
  len:number <- length *s
  result <- greater-or-equal idx, len
]