1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# new type to help incrementally read texts (arrays of characters)
container stream [
index:number
data:address:array:character
]
def new-stream s:address:array:character -> result:address:stream [
local-scope
load-ingredients
result <- new stream:type
*result <- put *result, index:offset, 0
*result <- put *result, data:offset, s
]
def rewind in:address:stream -> in:address:stream [
local-scope
load-ingredients
*in <- put *in, index:offset, 0
]
def read in:address:stream -> result:character, in:address:stream [
local-scope
load-ingredients
idx:number <- get *in, index:offset
s:address:array:character <- get *in, data:offset
len:number <- length *s
at-end?:boolean <- greater-or-equal idx len
reply-if at-end?, 0/nul, in
result <- index *s, idx
idx <- add idx, 1
*in <- put *in, index:offset, idx
]
def peek in:address:stream -> result:character [
local-scope
load-ingredients
idx:number <- get *in, index:offset
s:address:array:character <- get *in, data:offset
len:number <- length *s
at-end?:boolean <- greater-or-equal idx len
reply-if at-end?, 0/nul
result <- index *s, idx
]
def read-line in:address:stream -> result:address:array:character, in:address:stream [
local-scope
load-ingredients
idx:number <- get *in, index:offset
s:address:array:character <- get *in, data:offset
next-idx:number <- find-next s, 10/newline, idx
result <- copy-range s, idx, next-idx
idx <- add next-idx, 1 # skip newline
# write back
*in <- put *in, index:offset, idx
]
def end-of-stream? in:address:stream -> result:boolean [
local-scope
load-ingredients
idx:number <- get *in, index:offset
s:address:array:character <- get *in, data:offset
len:number <- length *s
result <- greater-or-equal idx, len
]
|