src/common.h

## deleting sandboxes

scenario deleting-sandboxes [
  local-scope
  trace-until 100/app  # trace too long
  assume-screen 100/width, 15/height
  env:&:environment <- new-programming-environment screen, [], []
  # run a few commands
  assume-console [
    left-click 1, 80
    type [divide-with-remainder 11, 3]
    press F4
    type [add 2, 2]
    press F4
  ]
  event-loop screen, console, env
  screen-should-contain [
    .                                                                                 run (F4)           .
    .                                                  ┊                                                 .
    .┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┊─────────────────────────────────────────────────.
    .                                                  ┊0   edit          copy            delete         .
    .                                                  ┊add 2, 2                                         .
    .                                                  ┊4                                                .
    .                                                  ┊─────────────────────────────────────────────────.
    .                                                  ┊1   edit          copy            delete         .
    .                                                  ┊divide-with-remainder 11, 3                      .
    .                                                  ┊3                                                .
    .                                                  ┊2                                                .
    .                                                  ┊─────────────────────────────────────────────────.
    .                                                  ┊                                                 .
  ]
  # delete second sandbox by clicking on left edge of 'delete' button
  assume-console [
    left-click 7, 85
  ]
  run [
    event-loop screen, console, env
  ]
  screen-should-contain [
    .                                                                                 run (F4)           .
    .                                                  ┊                                                 .
    .┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┊─────────────────────────────────────────────────.
    .                                                  ┊0   edit          copy            delete         .
    .                                                  ┊add 2, 2                                         .
    .                                                  ┊4                                                .
    .                                                  ┊─────────────────────────────────────────────────.
    .                                                  ┊                                                 .
    .                                                  ┊                                                 .
  ]
  # delete first sandbox by clicking at right edge of 'delete' button
  assume-console [
    left-click 3, 99
  ]
  run [
    event-loop screen, console, env
  ]
  screen-should-contain [
    .                                                                                 run (F4)           .
    .                                                  ┊                                                 .
    .┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┊─────────────────────────────────────────────────.
    .                                                  ┊                                                 .
    .                                                  ┊                                                 .
  ]
]

after <global-touch> [
  # support 'delete' button
  {
    delete?:bool <- should-attempt-delete? click-row, click-column, env
    break-unless delete?
    delete?, env <- try-delete-sandbox click-row, env
    break-unless delete?
    hide-screen screen
    screen <- render-sandbox-side screen, env, render
    screen <- update-cursor screen, recipes, current-sandbox, sandbox-in-focus?, env
    show-screen screen
    loop +next-event:label
  }
]

# some preconditions for attempting to delete a sandbox
def should-attempt-delete? click-row:num, click-column:num, env:&:environment -> result:bool [
  local-scope
  load-ingredients
  # are we below the sandbox editor?
  click-sandbox-area?:bool <- click-on-sandbox-area? click-row, click-column, env
  reply-unless click-sandbox-area?, 0/false
  # narrower, is the click in the columns spanning the 'copy' button?
  first-sandbox:&:editor <- get *env, current-sandbox:offset
  assert first-sandbox, [!!]
  sandbox-left-margin:num <- get *first-sandbox, left:offset
  sandbox-right-margin:num <- get *first-sandbox, right:offset
  _, _, _, _, delete-button-left:num <- sandbox-menu-columns sandbox-left-margin, sandbox-right-margin
  result <- within-range? click-column, delete-button-left, sandbox-right-margin
]

def try-delete-sandbox click-row:num, env:&:environment -> clicked-on-delete-button?:bool, env:&:environment [
  local-scope
  load-ingredients
  # identify the sandbox to delete, if the click was actually on the 'delete' button
  sandbox:&:sandbox <- find-sandbox env, click-row
  return-unless sandbox, 0/false
  clicked-on-delete-button? <- copy 1/true
  env <- delete-sandbox env, sandbox
]

def delete-sandbox env:&:environment, sandbox:&:sandbox -> env:&:environment [
  local-scope
  load-ingredients
  curr-sandbox:&:sandbox <- get *env, sandbox:offset
  first-sandbox?:bool <- equal curr-sandbox, sandbox
  {
    # first sandbox? pop
    break-unless first-sandbox?
    next-sandbox:&:sandbox <- get *curr-sandbox, next-sandbox:offset
    *env <- put *env, sandbox:offset, next-sandbox
  }
  {
    # not first sandbox?
    break-if first-sandbox?
    prev-sandbox:&:sandbox <- copy curr-sandbox
    curr-sandbox <- get *curr-sandbox, next-sandbox:offset
    {
      assert curr-sandbox, [sandbox not found! something is wrong.]
      found?:bool <- equal curr-sandbox, sandbox
      break-if found?
      prev-sandbox <- copy curr-sandbox
      curr-sandbox <- get *curr-sandbox, next-sandbox:offset
      loop
    }
    # snip sandbox out of its list
    next-sandbox:&:sandbox <- get *curr-sandbox, next-sandbox:offset
    *prev-sandbox <- put *prev-sandbox, next-sandbox:offset, next-sandbox
  }
  # update sandbox count
  sandbox-count:num <- get *env, number-of-sandboxes:offset
  sandbox-count <- subtract sandbox-count, 1
  *env <- put *env, number-of-sandboxes:offset, sandbox-count
  # reset scroll if deleted sandbox was last
  {
    break-if next-sandbox
    render-from:num <- get *env, render-from:offset
    reset-scroll?:bool <- equal render-from, sandbox-count
    break-unless reset-scroll?
    *env <- put *env, render-from:offset, -1
  }
]

scenario deleting-sandbox-after-scroll [
  local-scope
  trace-until 100/app  # trace too long
  assume-screen 100/width, 10/height
  # initialize environment
  env:&:environment <- new-programming-environment screen, [], []
  render-all screen, env, render
  # create 2 sandboxes and scroll to second
  assume-console [
    press ctrl-n
    type [add 2, 2]
    press F4
    type [add 1, 1]
    press F4
    press page-down
  ]
  event-loop screen, console, env
  screen-should-contain [
    .                                                                                 run (F4)           .
    .                                                  ┊─────────────────────────────────────────────────.
    .┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┊0   edit          copy            delete         .
    .                                                  ┊add 1, 1                                         .
    .                                                  ┊2                                                .
    .                                                  ┊─────────────────────────────────────────────────.
    .                                                  ┊1   edit          copy            delete         .
  ]
  # delete the second sandbox
  assume-console [
    left-click 6, 99
  ]
  run [
    event-loop screen, console, env
  ]
  # second sandbox shows in editor; scroll resets to display first sandbox
  screen-should-contain [
    .                                                                                 run (F4)           .
    .                                                  ┊─────────────────────────────────────────────────.
    .┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┊0   edit          copy            delete         .
    .                                                  ┊add 1, 1                                         .
    .                                                  ┊2                                                .
    .                                                  ┊─────────────────────────────────────────────────.
    .                                                  ┊                                                 .
  ]
]

scenario deleting-top-sandbox-after-scroll [
  local-scope
  trace-until 100/app  # trace too long
  assume-screen 100/width, 10/height
  # initialize environment
  env:&:environment <- new-programming-environment screen, [], []
  render-all screen, env, render
  # create 2 sandboxes and scroll to second
  assume-console [
    press ctrl-n
    type [add 2, 2]
    press F4
    type [add 1, 1]
    press F4
    press page-down
  ]
  event-loop screen, console, env
  screen-should-contain [
    .                                                                                 run (F4)           .
    .                                                  ┊─────────────────────────────────────────────────.
    .┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┊0   edit          copy            delete         .
    .                                                  ┊add 1, 1                                         .
    .                                                  ┊2                                                .
    .                                                  ┊─────────────────────────────────────────────────.
    .                                                  ┊1   edit          copy            delete         .
  ]
  # delete the second sandbox
  assume-console [
    left-click 2, 99
  ]
  run [
    event-loop screen, console, env
  ]
  # second sandbox shows in editor; scroll resets to display first sandbox
  screen-should-contain [
    .                                                                                 run (F4)           .
    .                                                  ┊─────────────────────────────────────────────────.
    .┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┊0   edit          copy            delete         .
    .                                                  ┊add 2, 2                                         .
    .                                                  ┊4                                                .
    .                                                  ┊─────────────────────────────────────────────────.
    .                                                  ┊                                                 .
  ]
]

scenario deleting-final-sandbox-after-scroll [
  local-scope
  trace-until 100/app  # trace too long
  assume-screen 100/width, 10/height
  # initialize environment
  env:&:environment <- new-programming-environment screen, [], []
  render-all screen, env, render
  # create 2 sandboxes and scroll to second
  assume-console [
    press ctrl-n
    type [add 2, 2]
    press F4
    type [add 1, 1]
    press F4
    press page-down
    press page-down
  ]
  event-loop screen, console, env
  screen-should-contain [
    .                                                                                 run (F4)           .
    .                                                  ┊─────────────────────────────────────────────────.
    .┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┊1   edit          copy            delete         .
    .                                                  ┊add 2, 2                                         .
    .                                                  ┊4                                                .
    .                                                  ┊─────────────────────────────────────────────────.
    .                                                  ┊                                                 .
  ]
  # delete the second sandbox
  assume-console [
    left-click 2, 99
  ]
  run [
    event-loop screen, console, env
  ]
  # implicitly scroll up to first sandbox
  screen-should-contain [
    .                                                                                 run (F4)           .
    .                                                  ┊                                                 .
    .┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┊─────────────────────────────────────────────────.
    .                                                  ┊0   edit          copy            delete         .
    .                                                  ┊add 1, 1                                         .
    .                                                  ┊2                                                .
    .                                                  ┊─────────────────────────────────────────────────.
    .                                                  ┊                                                 .
  ]
]

scenario deleting-updates-sandbox-count [
  local-scope
  trace-until 100/app  # trace too long
  assume-screen 100/width, 10/height
  # initialize environment
  env:&:environment <- new-programming-environment screen, [], []
  render-all screen, env, render
  # create 2 sandboxes
  assume-console [
    press ctrl-n
    type [add 2, 2]
    press F4
    type [add 1, 1]
    press F4
  ]
  event-loop screen, console, env
  screen-should-contain [
    .                                                                                 run (F4)           .
    .                                                  ┊                                                 .
    .┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┊─────────────────────────────────────────────────.
    .                                                  ┊0   edit          copy            delete         .
    .                                                  ┊add 1, 1                                         .
    .                                                  ┊2                                                .
    .                                                  ┊─────────────────────────────────────────────────.
    .                                                  ┊1   edit          copy            delete         .
    .                                                  ┊add 2, 2                                         .
    .                                                  ┊4                                                .
  ]
  # delete the second sandbox, then try to scroll down twice
  assume-console [
    left-click 3, 99
    press page-down
    press page-down
  ]
  run [
    event-loop screen, console, env
  ]
  # shouldn't go past last sandbox
  screen-should-contain [
    .                                                                                 run (F4)           .
    .                                                  ┊─────────────────────────────────────────────────.
    .┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┊0   edit          copy            delete         .
    .                                                  ┊add 2, 2                                         .
    .                                                  ┊4                                                .
    .                                                  ┊─────────────────────────────────────────────────.
    .                                                  ┊                                                 .
  ]
]
	Commit message (Expand)	Author	Age	Files	Lines
*	Update copyright to include 2019	Michael Vetter	2019-01-22	1	-1/+1
*	Merge pull request #1011 from jubalh/sha1	Michael Vetter	2018-09-19	1	-2/+0
\|\
\| *	Move p_sha1_hash() to stanza.c	Michael Vetter	2018-09-06	1	-2/+0
* \|	use gio functions for file copy	Philip Flohr	2018-09-06	1	-1/+1
\|/
*	Move ID generation to xmpp folder	Michael Vetter	2018-08-30	1	-1/+0
*	Use uuid in create_unique_id instead of counter	Michael Vetter	2018-08-14	1	-1/+0
*	Update copyright	James Booth	2018-01-21	1	-1/+1
*	Update Glib dependency to 2.40	James Booth	2017-03-25	1	-20/+0
*	Allow installing plugins from directory	James Booth	2017-02-05	1	-0/+4
*	Update Copyright	James Booth	2017-01-28	1	-1/+1
*	Move window functions to window_list.c	James Booth	2016-07-24	1	-3/+1
*	Move resource conversions	James Booth	2016-07-24	1	-6/+1
*	Add config/files.c	James Booth	2016-07-24	1	-2/+0
*	Update GPL link in headers	James Booth	2016-07-24	1	-1/+1
*	Add /plugins install command	James Booth	2016-07-12	1	-0/+1
*	Added whole word matches for room mention	James Booth	2016-04-07	1	-1/+2
*	Added prof_strstr function	James Booth	2016-04-03	1	-1/+2
*	Updated copyright	James Booth	2016-02-14	1	-1/+1
*	Applied coding style to src/	James Booth	2015-10-26	1	-2/+1
*	Use consistent style for pointers	Michael Vetter	2015-10-21	1	-13/+13
*	Create is_notify_enabled function	Michael Vetter	2015-10-12	1	-0/+1
*	Fixed OTR decryption check	James Booth	2015-08-27	1	-1/+1
*	Added str_contains_str to common	James Booth	2015-08-26	1	-0/+1
*	I removed ncurses header dependencies, removed unused code	James Booth	2015-06-15	1	-7/+0
*	Added more connect tests	James Booth	2015-05-24	1	-0/+1
*	Moved _strtoi to common, strtoi_range	James Booth	2015-03-16	1	-0/+1
*	Merge branch 'master' into readline	James Booth	2015-02-11	1	-1/+1
\|\
\| *	Updated copyright	James Booth	2015-02-10	1	-1/+1
* \|	Merge branch 'master' into readline	James Booth	2015-02-08	1	-0/+1
\|\\|
\| *	Moved quote stripper to common, added tests	James Booth	2015-02-08	1	-0/+1
* \|	Refactor inputwin.c	James Booth	2015-01-18	1	-0/+8
\|/
*	Added utf8_display_len	James Booth	2015-01-17	1	-0/+1
*	Simplified autocompleters and command history	James Booth	2015-01-16	1	-1/+1
*	fgets: buffer size	Peter Vilim	2015-01-07	1	-0/+5
*	Follow symlinks for profrc and accounts files	James Booth	2014-10-26	1	-0/+2
*	Added license exemption for OpenSSL to source headers	James Booth	2014-08-24	1	-0/+12
*	Renamed generate_unique_id -> create_unique_id	James Booth	2014-06-15	1	-1/+1
*	Renamed sha1 functions to avoid naming clashes	James Booth	2014-06-15	1	-1/+1
*	Fixed define for g_hash_table_contains (glib < 2.32)	James Booth	2014-05-22	1	-1/+1
*	Added g_hash_table_contains for glib < 2.32	James Booth	2014-05-22	1	-0/+2
*	Added glib g_hash_table_add for glib < 2.32	James Booth	2014-05-22	1	-0/+6
*	Added backwards compatible g_list_free_full for glib < 2.28	James Booth	2014-05-21	1	-0/+2
*	Changed to use gnutls instead of openssl for sha1 hashing	James Booth	2014-05-01	1	-0/+1
*	Updated copyright	James Booth	2014-03-09	1	-1/+1
*	generate_unique_id allows prefix	James Booth	2014-01-25	1	-1/+1
*	Removed unused encode.xml	James Booth	2014-01-21	1	-1/+0
*	Removed limit on number of windows, WIP	James Booth	2013-08-27	1	-1/+1
*	Added function to get next available window number, and tests	James Booth	2013-08-27	1	-0/+3
*	remove octet_compare	Dmitry Podgorny	2013-08-26	1	-1/+0
*	refactored mkdir_recursive	Dmitry Podgorny	2013-08-03	1	-2/+2